# Maintainer: Biswapriyo Nath <nathbappai@gmail.com>

_realname=trio
pkgbase=mingw-w64-python-${_realname}
pkgname=("${MINGW_PACKAGE_PREFIX}-python-${_realname}")
pkgver=0.31.0
pkgrel=1
pkgdesc="A friendly Python library for async concurrency and I/O (mingw-w64)"
arch=('any')
mingw_arch=('mingw64' 'ucrt64' 'clang64' 'clangarm64')
msys2_references=(
  'anitya: 17451'
  'archlinux: python-trio'
  'gentoo: dev-python/trio'
  'purl: pkg:pypi/trio'
)
msys2_repository_url='https://github.com/python-trio/trio/'
url='https://trio.readthedocs.io/'
msys2_changelog_url='https://trio.readthedocs.io/en/stable/history.html'
license=('spdx:Apache-2.0 OR MIT')
depends=(
  "${MINGW_PACKAGE_PREFIX}-python"
  "${MINGW_PACKAGE_PREFIX}-python-attrs"
  "${MINGW_PACKAGE_PREFIX}-python-cffi"
  "${MINGW_PACKAGE_PREFIX}-python-idna"
  "${MINGW_PACKAGE_PREFIX}-python-outcome"
  "${MINGW_PACKAGE_PREFIX}-python-sniffio"
  "${MINGW_PACKAGE_PREFIX}-python-sortedcontainers"
)
makedepends=(
  "${MINGW_PACKAGE_PREFIX}-python-build"
  "${MINGW_PACKAGE_PREFIX}-python-installer"
  "${MINGW_PACKAGE_PREFIX}-python-setuptools"
)
source=("https://pypi.org/packages/source/${_realname::1}/${_realname}/${_realname}-${pkgver}.tar.gz")
sha256sums=('f71d551ccaa79d0cb73017a33ef3264fde8335728eb4c6391451fe5d253a9d5b')

build() {
  cp -r "${_realname}-${pkgver}" "python-build-${MSYSTEM}" && cd "python-build-${MSYSTEM}"
  ${MINGW_PREFIX}/bin/python -m build --wheel --skip-dependency-check --no-isolation
}

package() {
  cd "${srcdir}/python-build-${MSYSTEM}"

  MSYS2_ARG_CONV_EXCL="--prefix=" \
    ${MINGW_PREFIX}/bin/python -m installer --prefix=${MINGW_PREFIX} \
    --destdir="${pkgdir}" dist/*.whl

  install -Dm644 LICENSE "${pkgdir}${MINGW_PREFIX}/share/licenses/python-${_realname}/LICENSE"
}
