# Maintainer: Konstantin Podsvirov <konstantin@podsvirov.su>

_realname=redis
pkgbase=mingw-w64-python-${_realname}
pkgname=("${MINGW_PACKAGE_PREFIX}-python-${_realname}")
pkgver=6.4.0
pkgrel=1
pkgdesc="The Python interface to the Redis key-value store (mingw-w64)"
arch=('any')
mingw_arch=('mingw64' 'ucrt64' 'clang64' 'clangarm64')
url='https://github.com/redis/redis-py'
msys2_references=(
  'purl: pkg:pypi/redis'
)
license=('spdx:MIT')
depends=("${MINGW_PACKAGE_PREFIX}-python-async-timeout")
makedepends=("${MINGW_PACKAGE_PREFIX}-python-build"
             "${MINGW_PACKAGE_PREFIX}-python-hatchling"
             "${MINGW_PACKAGE_PREFIX}-python-installer")
optdepends=("${MINGW_PACKAGE_PREFIX}-python-hiredis: faster performance via hiredis"
            "${MINGW_PACKAGE_PREFIX}-python-cryptography: OCSP certificate validation"
            "${MINGW_PACKAGE_PREFIX}-python-pyopenssl: OCSP certificate validation"
            "${MINGW_PACKAGE_PREFIX}-python-requests: OCSP certificate validation")
source=("https://pypi.org/packages/source/${_realname::1}/${_realname}/${_realname}-${pkgver}.tar.gz")
sha256sums=('b01bc7282b8444e28ec36b261df5375183bb47a07eb9c603f284e89cbc5ef010')

build() {
  cp -r "${_realname}-${pkgver}" "python-build-${MSYSTEM}" && cd "python-build-${MSYSTEM}"
  ${MINGW_PREFIX}/bin/python -m build --wheel --skip-dependency-check --no-isolation
}

package() {
  cd "${srcdir}/python-build-${MSYSTEM}"

  MSYS2_ARG_CONV_EXCL="--prefix=" \
    ${MINGW_PREFIX}/bin/python -m installer --prefix=${MINGW_PREFIX} \
    --destdir="${pkgdir}" dist/*.whl

  install -Dm644 LICENSE "${pkgdir}${MINGW_PREFIX}/share/licenses/python-${_realname}/LICENSE"
}
