# Maintainer: Alexandros Theodotou <alex at zrythm dot org>

_realname=lsp-dsp-lib
pkgbase=mingw-w64-${_realname}
pkgname="${MINGW_PACKAGE_PREFIX}-${_realname}"
pkgver=1.0.16
pkgrel=1
pkgdesc='SIMD-optimized library for digital signal processing (mingw-w64)'
arch=('any')
mingw_arch=('mingw32' 'mingw64' 'ucrt64')
makedepends=("${MINGW_PACKAGE_PREFIX}-cc"
             "${MINGW_PACKAGE_PREFIX}-make")
license=('LGPL3')
url="https://github.com/lsp-plugins/${_realname}"
source=("https://github.com/lsp-plugins/$_realname/releases/download/$pkgver/$_realname-src-$pkgver.tar.gz")
sha256sums=('9b0e11daa8c9ca5970f18e503f1be430044bf812a116cf73389ab1bba503f186')

build() {
  cd "${srcdir}/${_realname}"

  make config PREFIX=${MINGW_PREFIX} ARCHITECTURE=${CARCH}
  make
}

package() {
  cd "${srcdir}/${_realname}"

  make DESTDIR=${pkgdir} install
  mkdir -p "${pkgdir}${MINGW_PREFIX}/bin"
  mv "${pkgdir}${MINGW_PREFIX}/lib/"*.dll "${pkgdir}${MINGW_PREFIX}/bin"

  for file in COPYING COPYING.LESSER; do
    install -Dm644 $file "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/$file"
  done
}
