# Maintainer: Alexey Pavlov <alexpux@gmail.com>

_realname=gtkimageview
pkgbase=mingw-w64-${_realname}
pkgname="${MINGW_PACKAGE_PREFIX}-${_realname}"
pkgver=1.6.4
pkgrel=3
pkgdesc="Simple image viewer widget for GTK2 (mingw-w64)"
arch=('any')
url="https://github.com/GNOME/gtkimageview"
license=("LGPL2.1")
makedepends=("${MINGW_PACKAGE_PREFIX}-gcc")
depends=("${MINGW_PACKAGE_PREFIX}-gtk2")
options=('strip' 'staticlibs')
source=("${_realname}-${pkgver}.tar.gz"
        "resources.tar.bz2"
        resource.patch
        g_mem_set_vtable.patch)
sha256sums=('4c681d38d127ee3950a29bce9aa7aa8a2abe3b4d915f7a0c88e526999c1a46f2'
            'bb255c8786e2039168801a9f49eb0f1fe38321842cd4967ec67f698883a90d86'
            '438c3c45f24cb367a9ba8567d9aa85775be9b1edda03a7101d6023a4dd04942c'
            'f2ba3dd4b6d1ad8f81953e2d51e43396df6606dab84211aec1095329514ebd5e')

prepare() {
  mv -f *.png ${_realname}-${pkgver}/src/
  cd "${srcdir}/${_realname}-${pkgver}"
  patch -p1 -i ${srcdir}/resource.patch
  patch -p1 -i ${srcdir}/g_mem_set_vtable.patch
  
  autoreconf -fiv
}

build() {
  export lt_cv_deplibs_check_method='pass_all'
  rm -rf "${srcdir}/build-${MINGW_CHOST}"
  mkdir "${srcdir}/build-${MINGW_CHOST}"
  cd "${srcdir}/build-${MINGW_CHOST}"
  ../${_realname}-${pkgver}/configure \
    --prefix=${MINGW_PREFIX} \
    --build=${MINGW_CHOST} \
    --host=${MINGW_CHOST} \
    --target=${MINGW_CHOST}

  make
}

package() {
  cd "${srcdir}/build-${MINGW_CHOST}"
  make DESTDIR="${pkgdir}" install
}
