# Maintainer (MSYS2): Michael Hansen <zrax0111@gmail.com>

_variant=-${KF5_VARIANT:-shared}
source "$(dirname ${BASH_SOURCE[0]})"/../mingw-w64-PKGBUILD-common/kde-frameworks5
_realname=kate
pkgbase=mingw-w64-${_realname}
pkgname="${MINGW_PACKAGE_PREFIX}-kate"
pkgver=18.08.1
pkgrel=2
arch=('any')
license=('GPL' 'LGPL' 'FDL')
url="https://www.kde.org/applications/utilities/kate/"
pkgdesc="Advanced Text Editor"
groups=(kde-applications kdebase)
makedepends=("${MINGW_PACKAGE_PREFIX}-extra-cmake-modules")
depends=("${MINGW_PACKAGE_PREFIX}-knewstuff-qt5${_namesuff}"
         "${MINGW_PACKAGE_PREFIX}-ktexteditor-qt5${_namesuff}"
         "${MINGW_PACKAGE_PREFIX}-threadweaver-qt5${_namesuff}"
         "${MINGW_PACKAGE_PREFIX}-kitemmodels-qt5${_namesuff}"
         "${MINGW_PACKAGE_PREFIX}-kactivities-qt5${_namesuff}"
         "${MINGW_PACKAGE_PREFIX}-plasma-framework-qt5${_namesuff}"
         "${MINGW_PACKAGE_PREFIX}-hicolor-icon-theme")
optdepends=("${MINGW_PACKAGE_PREFIX}-breeze-icons-qt5${_namesuff}: application icon theme"
            "${MINGW_PACKAGE_PREFIX}-kinit-qt5${_namesuff}: file system browser plugin")
source=("https://download.kde.org/stable/applications/${pkgver}/src/${_realname}-${pkgver}.tar.xz")
sha256sums=('4afb79472935ed172e74a72e0008a0b9078523a07d831e16736638e7a4994dcb')

prepare() {
  mkdir -p build-${CARCH}${_variant}
}

build() {
  local -a extra_config
  cd build-${CARCH}${_variant}
  if [ "${_variant}" = "-static" ]; then
    extra_config+=( -DBUILD_SHARED_LIBS=NO )
  fi

  _kde_f5_build_env
  cmake ../${_realname}-${pkgver} \
    -DCMAKE_BUILD_TYPE=$(_kde_f5_CMAKE_BUILD_TYPE) \
    "${_kde_f5_KDE_INSTALL_DIRS[@]}" \
    -DBUILD_QCH=OFF \
    -DBUILD_TESTING=OFF \
    -DECM_DIR=${MINGW_PREFIX}/share/ECM \
    "${extra_config[@]}" \
    -G'MSYS Makefiles'
  make
}

package() {
  cd build-${CARCH}${_variant}
  make DESTDIR="${pkgdir}" install
}
