# Maintainer: J. Peter Mugaas <jpmugaas@suddenlink.net>

_realname=pytest-xdist
pkgbase=mingw-w64-python-${_realname}
pkgname=("${MINGW_PACKAGE_PREFIX}-python2-${_realname}"  "${MINGW_PACKAGE_PREFIX}-python3-${_realname}")
pkgver=1.25.0
pkgrel=1
pkgdesc="py.test xdist plugin for distributed testing and loop-on-failing modes (mingw-w64)"
arch=('any')
url='https://bitbucket.org/pytest-dev/pytest-xdist'
validpgpkeys=('gpg_KEY')
makedepends=("${MINGW_PACKAGE_PREFIX}-python2"
             "${MINGW_PACKAGE_PREFIX}-python3"
             "${MINGW_PACKAGE_PREFIX}-python3-pytest"
             "${MINGW_PACKAGE_PREFIX}-python2-pytest"
             "${MINGW_PACKAGE_PREFIX}-python3-pytest-forked"
             "${MINGW_PACKAGE_PREFIX}-python2-pytest-forked"
             "${MINGW_PACKAGE_PREFIX}-python3-execnet"
             "${MINGW_PACKAGE_PREFIX}-python2-execnet"
             "${MINGW_PACKAGE_PREFIX}-python2-filelock"
             "${MINGW_PACKAGE_PREFIX}-python3-filelock"
             "${MINGW_PACKAGE_PREFIX}-python3-setuptools"
             "${MINGW_PACKAGE_PREFIX}-python2-setuptools"
             "${MINGW_PACKAGE_PREFIX}-python3-setuptools-scm"
             "${MINGW_PACKAGE_PREFIX}-python2-setuptools-scm")
options=('staticlibs' 'strip' '!debug')
source=("${_realname}-$pkgver.tar.gz"::"https://github.com/pytest-dev/pytest-xdist/archive/v$pkgver.tar.gz")
sha512sums=('0de788107dae37e1cd845b0f170d06fe0c560a7f4e2caa95069af78ff0ca2e4eab11838e17979e0482057a668f1741c1f6c8be35532309aca3d2c9caaecab527')

prepare() {
  cd "${srcdir}"
  for builddir in python{2,3}-build-${CARCH}; do
    rm -rf ${builddir} | true
    cp -r "${_realname}-${pkgver}" "${builddir}"
  done
  # Set version for setuptools_scm
  export SETUPTOOLS_SCM_PRETEND_VERSION=$pkgver
}

build() {
  for pver in {2,3}; do  
    msg "Python ${pver} build for ${CARCH}"  
    cd "${srcdir}/python${pver}-build-${CARCH}"
    ${MINGW_PREFIX}/bin/python${pver} setup.py build
  done  
}

check() {
# Hack entry points by installing it
  local OLD_PYTHON_PATH=$PYTHONPATH
  msg "Python 2 test for ${CARCH}"
  cd "${srcdir}/python2-build-${CARCH}"
  MSYS2_ARG_CONV_EXCL="--prefix=;--install-scripts=;--install-platlib=" \
    ${MINGW_PREFIX}/bin/python2 setup.py install --root="$PWD/tmp_install" --optimize=1 --skip-build
  _PATHONPATH1="${srcdir}/python2-build-${CARCH}/tmp_install${MINGW_PREFIX}/lib/python2.7/site-packages"
  _PATHONPATH2="${OLD_PYTHON_PATH};${srcdir}/python2-build-${CARCH}/tests"
  PYTHONPATH="${_PATHONPATH1};${_PATHONPATH2}" py.test2 || true

  msg "Python 3 test for ${CARCH}"
  cd "${srcdir}/python3-build-${CARCH}"
  MSYS2_ARG_CONV_EXCL="--prefix=;--install-scripts=;--install-platlib=" \
    ${MINGW_PREFIX}/bin/python3 setup.py install --root="$PWD/tmp_install" --optimize=1 --skip-build
  _PATHONPATH1="${srcdir}/python3-build-${CARCH}/tmp_install${MINGW_PREFIX}/lib/python3.7/site-packages"
  _PATHONPATH2="${OLD_PYTHON_PATH};${srcdir}/python3-build-${CARCH}/tests"
  PYTHONPATH="${_PATHONPATH1};${_PATHONPATH2}" py.test || true

}

package_python3-pytest-xdist() {
  depends=("${MINGW_PACKAGE_PREFIX}-python3"
           "${MINGW_PACKAGE_PREFIX}-python3-pytest-forked" 
           "${MINGW_PACKAGE_PREFIX}-python3-execnet")

  cd "${srcdir}/python3-build-${CARCH}"
  MSYS2_ARG_CONV_EXCL="--prefix=;--install-scripts=;--install-platlib=" \
  ${MINGW_PREFIX}/bin/python3 setup.py install --prefix=${MINGW_PREFIX} \
    --root="${pkgdir}" --optimize=1 --skip-build

  install -Dm644 LICENSE "${pkgdir}${MINGW_PREFIX}/share/licenses/python3-${_realname}/LICENSE"
}

package_python2-pytest-xdist() {
  depends=("${MINGW_PACKAGE_PREFIX}-python2"
           "${MINGW_PACKAGE_PREFIX}-python2-pytest-forked" 
           "${MINGW_PACKAGE_PREFIX}-python2-execnet")

  cd "${srcdir}/python2-build-${CARCH}"
  MSYS2_ARG_CONV_EXCL="--prefix=;--install-scripts=;--install-platlib=" \
  ${MINGW_PREFIX}/bin/python2 setup.py install --prefix=${MINGW_PREFIX} \
    --root="${pkgdir}" --optimize=1 --skip-build

  install -Dm644 LICENSE "${pkgdir}${MINGW_PREFIX}/share/licenses/python2-${_realname}/LICENSE"
}

package_mingw-w64-i686-python2-pytest-xdist() {
  package_python2-pytest-xdist
}

package_mingw-w64-i686-python3-pytest-xdist() {
  package_python3-pytest-xdist
}

package_mingw-w64-x86_64-python2-pytest-xdist() {
  package_python2-pytest-xdist
}

package_mingw-w64-x86_64-python3-pytest-xdist() {
  package_python3-pytest-xdist
}
