From 00843ca0d8c6d85f1bcce3e67db36a9f6b4e1f58 Mon Sep 17 00:00:00 2001
From: Marcin Sielski <marcin.sielski@motorolasolutions.com>
Date: Tue, 18 Oct 2016 14:20:10 +0200
Subject: [PATCH] MQTT C Client (#1835)

* Add Eclipse Eclipse Paho MQTT C client support

* Add CMakeLists patch

* Fixes to PKGBUILD
---
 mingw-w64-paho.mqtt.c/0001-CMakeLists.patch | 12 +++++
 mingw-w64-paho.mqtt.c/PKGBUILD              | 54 +++++++++++++++++++++
 2 files changed, 66 insertions(+)
 create mode 100644 mingw-w64-paho.mqtt.c/0001-CMakeLists.patch
 create mode 100644 mingw-w64-paho.mqtt.c/PKGBUILD

diff --git a/mingw-w64-paho.mqtt.c/0001-CMakeLists.patch b/mingw-w64-paho.mqtt.c/0001-CMakeLists.patch
new file mode 100644
index 0000000000..9c59b98e71
--- /dev/null
+++ b/mingw-w64-paho.mqtt.c/0001-CMakeLists.patch
@@ -0,0 +1,12 @@
+--- origsrc/paho.mqtt.c-1.1.0/src/CMakeLists.txt	2016-06-20 01:00:10.000000000 +0200
++++ src/paho.mqtt.c-1.1.0/src/CMakeLists.txt	2016-10-16 21:08:35.069400000 +0200
+@@ -65,7 +65,8 @@
+     SOVERSION ${PAHO_VERSION_MAJOR})
+ INSTALL(TARGETS paho-mqtt3c paho-mqtt3a MQTTVersion
+     RUNTIME DESTINATION bin
+-    LIBRARY DESTINATION lib)
++    LIBRARY DESTINATION lib
++    ARCHIVE DESTINATION lib)
+ INSTALL(FILES MQTTAsync.h MQTTClient.h MQTTClientPersistence.h
+     DESTINATION include)
+ 
diff --git a/mingw-w64-paho.mqtt.c/PKGBUILD b/mingw-w64-paho.mqtt.c/PKGBUILD
new file mode 100644
index 0000000000..8a9e2f619b
--- /dev/null
+++ b/mingw-w64-paho.mqtt.c/PKGBUILD
@@ -0,0 +1,54 @@
+# Maintainer: Marcin Sielski <marcin.sielski(at)gmail.com>
+
+_realname=paho.mqtt.c
+pkgbase=mingw-w64-${_realname}
+pkgname=("${MINGW_PACKAGE_PREFIX}-${_realname}")
+pkgver=1.1.0
+pkgrel=1
+pkgdesc="Eclipse Paho MQTT C client (mingw-w64)"
+arch=('any')
+url='https://eclipse.org/paho/clients/c/'
+license=('EPL/EDL')
+makedepends=("${MINGW_PACKAGE_PREFIX}-cmake")
+options=('strip' 'staticlibs')
+source=("${_realname}-${pkgver}.tar.gz"::"https://github.com/eclipse/${_realname}/archive/v${pkgver}.tar.gz"
+        "0001-CMakeLists.patch")
+sha256sums=('970b9621efc24251441d386274cd0a90cf6ad52b64031f3c8cb53fdd5526f5f3'
+            '4163cf0db590d39f5b86aa54a0e5331b7e7e374e796748d6df78c8be30ceaf83')
+
+prepare() {
+  cd "$srcdir"/${_realname}-${pkgver}
+  patch -p2 -i ${srcdir}/0001-CMakeLists.patch
+}
+
+build() {
+  cd "$srcdir"/${_realname}-${pkgver}
+  [[ -d "${srcdir}"/build-${CARCH} ]] && rm -rf "${srcdir}"/build-${CARCH}
+  mkdir -p "${srcdir}"/build-${CARCH} && cd "${srcdir}"/build-${CARCH}
+
+  declare -a extra_config
+  if check_option "debug" "n"; then
+    extra_config+=("-DCMAKE_BUILD_TYPE=Release")
+  else
+    extra_config+=("-DCMAKE_BUILD_TYPE=Debug")
+  fi
+
+  MSYS2_ARG_CONV_EXCL="-DCMAKE_INSTALL_PREFIX=" \
+    ${MINGW_PREFIX}/bin/cmake \
+      -G'MSYS Makefiles' \
+      -DCMAKE_INSTALL_PREFIX=${MINGW_PREFIX} \
+      "${extra_config[@]}" \
+      -DBUILD_{SHARED,STATIC}_LIBS=ON \
+      ../${_realname}-${pkgver}
+
+  make
+}
+
+check() {
+  cd "${srcdir}"/build-${CARCH}
+}
+
+package() {
+  cd "${srcdir}"/build-${CARCH}
+  make install DESTDIR="${pkgdir}"
+}