matplotlib-inline: new package

mingw-w64-python-matplotlib-inline/PKGBUILD

@@ -0,0 +1,42 @@
+# Maintainer: Naveen M K <naveen@syrusdark.website>
+
+_pyname=matplotlib-inline
+_realname=matplotlib-inline
+pkgbase=mingw-w64-python-${_realname}
+pkgname=("${MINGW_PACKAGE_PREFIX}-python-${_realname}")
+pkgver=0.1.2
+pkgrel=1
+pkgdesc='Inline Matplotlib backend for Jupyter (mingw-w64)'
+arch=('any')
+url="https://pypi.org/project/matplotlib-inline/"
+license=('BSD-3-Clause')
+depends=(
+  "${MINGW_PACKAGE_PREFIX}-python"
+  "${MINGW_PACKAGE_PREFIX}-python-traitlets"
+)
+makedepends=(
+  "${MINGW_PACKAGE_PREFIX}-python-setuptools" 
+)
+source=("${_pyname}-${pkgver}.tar.gz::https://pypi.org/packages/source/${_pyname::1}/${_pyname}/${_pyname}-${pkgver}.tar.gz")
+sha256sums=('f41d5ff73c9f5385775d5c0bc13b424535c8402fe70ea8210f93e11f3683993e')
+
+prepare() {  
+  cd "$srcdir"
+  rm -rf python-build-${CARCH} | true
+  cp -r "${_pyname//_/-}-$pkgver" "python-build-${CARCH}"
+  export SETUPTOOLS_SCM_PRETEND_VERSION=${pkgver}
+}
+
+build() {
+  msg "Python build for ${CARCH}"  
+  cd "${srcdir}/python-build-${CARCH}"
+  ${MINGW_PREFIX}/bin/python setup.py build
+}
+
+package() {
+  cd "${srcdir}/python-build-${CARCH}"
+  MSYS2_ARG_CONV_EXCL="--prefix=;--install-scripts=;--install-platlib=" \
+  ${MINGW_PREFIX}/bin/python setup.py install --prefix=${MINGW_PREFIX} \
+    --root="${pkgdir}" --optimize=1 --skip-build
+  install -Dm644 LICENSE "${pkgdir}${MINGW_PREFIX}/share/licenses/python-${_realname}/LICENSE"
+}