From 292b22d2bb2cefd92e7e73e8908a6cdd686a7d99 Mon Sep 17 00:00:00 2001
From: Konstantin Podsvirov <konstantin@podsvirov.pro>
Date: Mon, 27 Mar 2023 18:41:04 +0300
Subject: [PATCH] umbrello: New package

---
 mingw-w64-umbrello/PKGBUILD | 72 +++++++++++++++++++++++++++++++++++++
 1 file changed, 72 insertions(+)
 create mode 100644 mingw-w64-umbrello/PKGBUILD

diff --git a/mingw-w64-umbrello/PKGBUILD b/mingw-w64-umbrello/PKGBUILD
new file mode 100644
index 0000000000..39b39705a0
--- /dev/null
+++ b/mingw-w64-umbrello/PKGBUILD
@@ -0,0 +1,72 @@
+# Maintainer: Konstantin Podsvirov <konstantin@podsvirov.pro>
+
+_variant=-${KF5_VARIANT:-shared}
+source "$(dirname ${BASH_SOURCE[0]})"/../mingw-w64-PKGBUILD-common/kde-frameworks5
+_realname=umbrello
+pkgbase=mingw-w64-${_realname}
+pkgname=("${MINGW_PACKAGE_PREFIX}-${_realname}")
+pkgver=23.04.0
+pkgrel=1
+arch=('any')
+mingw_arch=('mingw32' 'mingw64' 'ucrt64' 'clang64' 'clang32')
+license=('GPL' 'LGPL' 'FDL')
+url="https://apps.kde.org/umbrello/"
+pkgdesc="UML modeller (mingw-w64)"
+groups=("${MINGW_PACKAGE_PREFIX}-kdesdk")
+makedepends=("${MINGW_PACKAGE_PREFIX}-cc"
+             "${MINGW_PACKAGE_PREFIX}-clang-tools-extra"
+             "${MINGW_PACKAGE_PREFIX}-cmake"
+             "${MINGW_PACKAGE_PREFIX}-ninja"
+             "${MINGW_PACKAGE_PREFIX}-doxygen"
+             "${MINGW_PACKAGE_PREFIX}-graphviz"
+             "${MINGW_PACKAGE_PREFIX}-extra-cmake-modules"
+             "${MINGW_PACKAGE_PREFIX}-kdoctools-qt5${_namesuff}"
+             "${MINGW_PACKAGE_PREFIX}-icoutils")
+depends=("${MINGW_PACKAGE_PREFIX}-ki18n-qt5${_namesuff}"
+         "${MINGW_PACKAGE_PREFIX}-ktextwidgets-qt5${_namesuff}"
+         "${MINGW_PACKAGE_PREFIX}-ktexteditor-qt5${_namesuff}"
+         "${MINGW_PACKAGE_PREFIX}-kio-qt5${_namesuff}"
+         "${MINGW_PACKAGE_PREFIX}-kxmlgui-qt5${_namesuff}"
+         "${MINGW_PACKAGE_PREFIX}-knotifications-qt5${_namesuff}"
+         "${MINGW_PACKAGE_PREFIX}-kconfig-qt5${_namesuff}"
+         "${MINGW_PACKAGE_PREFIX}-kcoreaddons-qt5${_namesuff}"
+         "${MINGW_PACKAGE_PREFIX}-kdbusaddons-qt5${_namesuff}"
+         "${MINGW_PACKAGE_PREFIX}-kcrash-qt5${_namesuff}"
+         "${MINGW_PACKAGE_PREFIX}-hicolor-icon-theme")
+source=("https://download.kde.org/stable/release-service/${pkgver}/src/${_realname}-${pkgver}.tar.xz"{,.sig})
+sha256sums=('e8209ed8579e983016e1f4dae3a961a0a7a81892d6be00922c0bb07bb464a445'
+            'SKIP')
+validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid@kde.org>
+              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87  # Christoph Feck <cfeck@kde.org>
+              D81C0CB38EB725EF6691C385BB463350D6EF31EF) # Heiko Becker <heiko.becker@kde.org>
+
+build() {
+  [[ -d "${srcdir}/build-${MSYSTEM}${_variant}" ]] && rm -rf "${srcdir}/build-${MSYSTEM}${_variant}"
+  mkdir -p "${srcdir}/build-${MSYSTEM}${_variant}" && cd "${srcdir}/build-${MSYSTEM}${_variant}"
+
+  local -a extra_config
+
+  if [ "${_variant}" = "-static" ]; then
+    extra_config+=( -DBUILD_SHARED_LIBS=NO )
+  fi
+
+  _kde_f5_build_env
+  ${MINGW_PREFIX}/bin/cmake.exe \
+    -G"Ninja" \
+    -DCMAKE_BUILD_TYPE=$(_kde_f5_CMAKE_BUILD_TYPE) \
+    "${_kde_f5_KDE_INSTALL_DIRS[@]}" \
+    -DBUILD_QCH=OFF \
+    -DBUILD_TESTING=OFF \
+    -DBUILD_PHP_IMPORT=OFF \
+    -DECM_DIR=${MINGW_PREFIX}/share/ECM \
+    "${extra_config[@]}" \
+    ../${_realname}-${pkgver}
+
+  ${MINGW_PREFIX}/bin/cmake.exe --build .
+}
+
+package() {
+  cd "${srcdir}/build-${MSYSTEM}${_variant}"
+
+  DESTDIR="${pkgdir}" ${MINGW_PREFIX}/bin/cmake.exe --install .
+}