From 2e9728b36650e4f2f1ab4b7e71c15517c720421d Mon Sep 17 00:00:00 2001
From: Alexpux <alexey.pawlow@gmail.com>
Date: Sun, 28 Sep 2014 09:05:12 +0400
Subject: [PATCH] termcap: New package.

---
 mingw-w64-termcap/PKGBUILD | 50 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)
 create mode 100644 mingw-w64-termcap/PKGBUILD

diff --git a/mingw-w64-termcap/PKGBUILD b/mingw-w64-termcap/PKGBUILD
new file mode 100644
index 0000000000..cb24df979e
--- /dev/null
+++ b/mingw-w64-termcap/PKGBUILD
@@ -0,0 +1,50 @@
+# Maintainer: Alexey Pavlov <alexpux@gmail.com>
+
+_realname=termcap
+pkgname="${MINGW_PACKAGE_PREFIX}-${_realname}"
+#conflicts=("${MINGW_PACKAGE_PREFIX}-ncurses")
+#provides=("${MINGW_PACKAGE_PREFIX}-ncurses")
+pkgver=1.3.1
+pkgrel=1
+pkgdesc="Terminal feature database (mingw-w64)"
+arch=('any')
+url="ftp://ftp.gnu.org/gnu/termcap/"
+license=("GPL" "LGPL")
+makedepends=("${MINGW_PACKAGE_PREFIX}-gcc")
+depends=("${MINGW_PACKAGE_PREFIX}-gcc-libs")
+options=('staticlibs' 'strip')
+source=("http://ftp.gnu.org/gnu/termcap/${_realname}-${pkgver}.tar.gz")
+md5sums=('ffe6f86e63a3a29fa53ac645faaabdfa')
+
+prepare() {
+  cd "${srcdir}/${_realname}-${pkgver}"
+  autoconf
+}
+
+build() {
+  [ -d ${srcdir}/build-${MINGW_CHOST} ] && rm -rf ${srcdir}/build-${MINGW_CHOST}
+  mkdir ${srcdir}/build-${MINGW_CHOST}
+  cd ${srcdir}/build-${MINGW_CHOST}
+  
+  ../${_realname}-${pkgver}/configure \
+    --prefix=${MINGW_PREFIX} \
+    --build=${MINGW_CHOST} \
+    --host=${MINGW_CHOST} \
+    --target=${MINGW_CHOST} 
+
+  make
+  # Build a shared library.  No need for -fPIC on Windows.
+  ${MINGW_PREFIX}/bin/gcc -shared \
+    -Wl,--out-implib,libtermcap.dll.a \
+    -o libtermcap-0.dll \
+    termcap.o tparam.o version.o
+}
+
+package() {
+  cd  ${srcdir}/build-${MINGW_CHOST}
+  make install prefix="${pkgdir}${MINGW_PREFIX}" exec_prefix="${pkgdir}${MINGW_PREFIX}" oldincludedir=
+  rm -r "$pkgdir"${MINGW_PREFIX}/info/
+  mkdir -p "${pkgdir}"${MINGW_PREFIX}/{bin,lib}
+  install -m 0755 libtermcap-0.dll "${pkgdir}${MINGW_PREFIX}/bin"
+  install -m 0644 libtermcap.dll.a "${pkgdir}${MINGW_PREFIX}/lib"
+}