[new-package] libgridxc 2.1.0

mingw-w64-libgridxc/001-fix-install-dll.patch

@@ -0,0 +1,10 @@
+--- a/CMakeLists.txt
++++ b/CMakeLists.txt
+@@ -180,6 +180,7 @@
+     "${PROJECT_NAME}-lib"
+     EXPORT
+     "${PROJECT_NAME}-targets"
++    RUNTIME DESTINATION "${CMAKE_INSTALL_BINDIR}"
+     LIBRARY DESTINATION "${CMAKE_INSTALL_LIBDIR}"
+     ARCHIVE DESTINATION "${CMAKE_INSTALL_LIBDIR}"
+   )

mingw-w64-libgridxc/002-fix-pkgconf-file.patch

@@ -0,0 +1,36 @@
+--- a/config/CMakeLists.txt
++++ b/config/CMakeLists.txt
+@@ -40,6 +40,7 @@
+     DESTINATION "${CMAKE_INSTALL_LIBDIR}/cmake/${PROJECT_NAME}"
+   )
+ 
++  set(LIBRARY_OUTPUT_NAME gridxc)
+   configure_file(
+     "${CMAKE_CURRENT_SOURCE_DIR}/template.pkgconf"
+     "${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}.pc"
+--- a/CMakeLists.txt
++++ b/CMakeLists.txt
+@@ -39,6 +39,11 @@
+    message(STATUS "Setting BUILD_SHARED_LIBS to ${LIBGRIDXC_SHARED_LIBS}")
+ endif()
+ 
++set(
++  module-dir
++  "${PROJECT_NAME}/${CMAKE_Fortran_COMPILER_ID}-${CMAKE_Fortran_COMPILER_VERSION}"
++)
++
+ # General configuration information: Build_type, Config files...
+ add_subdirectory("config")
+ 
+@@ -135,11 +140,6 @@
+ 
+ endif()
+ 
+-set(
+-  module-dir
+-  "${PROJECT_NAME}/${CMAKE_Fortran_COMPILER_ID}-${CMAKE_Fortran_COMPILER_VERSION}"
+-)
+-
+ target_include_directories(
+   "${PROJECT_NAME}-lib"
+   PUBLIC

mingw-w64-libgridxc/PKGBUILD

@@ -0,0 +1,65 @@
+# Contributor: Mehdi Chinoune <mehdi.chinoune@hotmail.com>
+
+_realname=libgridxc
+pkgbase=mingw-w64-${_realname}
+pkgname=("${MINGW_PACKAGE_PREFIX}-${_realname}")
+pkgver=2.1.0
+pkgrel=1
+pkgdesc="Library for XC computation on grids. (mingw-w64)"
+arch=('any')
+mingw_arch=('ucrt64' 'clang64' 'clangarm64')
+url='https://gitlab.com/siesta-project/libraries/libgridxc'
+msys2_references=(
+  'aur: libgridxc'
+)
+license=('spdx:BSD-3-Clause')
+depends=("${MINGW_PACKAGE_PREFIX}-gcc-libs"
+         $([[ ${MINGW_PACKAGE_PREFIX} == *-clang-* ]] || echo "${MINGW_PACKAGE_PREFIX}-gcc-libgfortran")
+         "${MINGW_PACKAGE_PREFIX}-libxc")
+makedepends=("${MINGW_PACKAGE_PREFIX}-fc"
+             "${MINGW_PACKAGE_PREFIX}-cmake"
+             "${MINGW_PACKAGE_PREFIX}-ninja")
+source=("https://gitlab.com/siesta-project/libraries/libgridxc/-/archive/${pkgver}/${_realname}-${pkgver}.tar.bz2"
+        "001-fix-install-dll.patch"
+        "002-fix-pkgconf-file.patch")
+sha256sums=('58bedbeea073f30614148e5d6cbf32b572d92544990c43d525785d1654a4c5d7'
+            'cc8ab14119c097257f1aaf646f187346aaf5b98b1fed7755159d2ad650abf75a'
+            'cb14007fd0296258b1146e6cc5f355cde9b689d3f581fa2963d06b249fa2122a')
+
+prepare() {
+  cd "${srcdir}"/${_realname}-${pkgver}
+
+  patch -Np1 -i "${srcdir}"/001-fix-install-dll.patch
+  patch -Np1 -i "${srcdir}"/002-fix-pkgconf-file.patch
+}
+
+build() {
+  declare -a _extra_config
+  if check_option "debug" "n"; then
+    _extra_config+=("-DCMAKE_BUILD_TYPE=Release")
+  else
+    _extra_config+=("-DCMAKE_BUILD_TYPE=Debug")
+  fi
+
+  MSYS2_ARG_CONV_EXCL="-DCMAKE_INSTALL_PREFIX=" \
+    "${MINGW_PREFIX}"/bin/cmake.exe \
+      -GNinja \
+      -DCMAKE_INSTALL_PREFIX="${MINGW_PREFIX}" \
+      "${_extra_config[@]}" \
+      -DBUILD_SHARED_LIBS=ON \
+      -DCMAKE_DLL_NAME_WITH_SOVERSION=ON \
+      -DLIBGRIDXC_WITH_LIBXC=ON \
+      -DLIBGRIDXC_WITH_MPI=OFF \
+      -DLIBGRIDXC_TESTS=OFF \
+      -S "${_realname}-${pkgver}" \
+      -B "build-${MSYSTEM}"
+
+  "${MINGW_PREFIX}"/bin/cmake.exe --build "build-${MSYSTEM}"
+}
+
+package() {
+  DESTDIR="${pkgdir}" "${MINGW_PREFIX}"/bin/cmake.exe --install "build-${MSYSTEM}"
+
+  install -Dm644 "${srcdir}"/${_realname}-${pkgver}/COPYING \
+    "${pkgdir}"${MINGW_PREFIX}/share/licenses/${_realname}/COPYING
+}