Add packages for Python module mock and its dependencies pbr, funcsigs.

mingw-w64-python-funcsigs/PKGBUILD

@@ -0,0 +1,59 @@
+# Contributor: Frederic Wang <fred.wang@free.fr>
+
+_realname=funcsigs
+pkgbase=mingw-w64-python-${_realname}
+pkgname=("${MINGW_PACKAGE_PREFIX}-python2-${_realname}" "${MINGW_PACKAGE_PREFIX}-python3-${_realname}")
+pkgver=0.4
+pkgrel=1
+pkgdesc='Python function signatures from PEP362 for Python 2.6, 2.7 and 3.2+'
+arch=('any')
+url='https://github.com/testing-cabal/funcsigs'
+license=('ASL')
+makedepends=("${MINGW_PACKAGE_PREFIX}-python3"
+             "${MINGW_PACKAGE_PREFIX}-python2")
+source=("https://pypi.python.org/packages/source/f/${_realname}/${_realname}-${pkgver}.tar.gz")
+md5sums=('fb1d031f284233e09701f6db1281c2a5')
+
+prepare() {
+  cd "${srcdir}"
+  cp -r ${_realname}-${pkgver} python2-build
+  cp -r ${_realname}-${pkgver} python3-build
+}
+
+package_python3-funcsigs() {
+  depends=("${MINGW_PACKAGE_PREFIX}-python3")
+
+  cd ${srcdir}/python3-build
+  MSYS2_ARG_CONV_EXCL="--prefix=;--install-scripts=;--install-platlib=" \
+  ${MINGW_PREFIX}/bin/python3 setup.py install --prefix=${MINGW_PREFIX} \
+    --root="${pkgdir}" --optimize=1
+
+  install -Dm644 LICENSE "${pkgdir}${MINGW_PREFIX}/share/licenses/python3-${_realname}/LICENSE"
+}
+
+package_python2-funcsigs() {
+  depends=("${MINGW_PACKAGE_PREFIX}-python2")
+
+  cd ${srcdir}/python2-build
+  MSYS2_ARG_CONV_EXCL="--prefix=;--install-scripts=;--install-platlib=" \
+  ${MINGW_PREFIX}/bin/python2 setup.py install --prefix=${MINGW_PREFIX} \
+    --root="${pkgdir}" --optimize=1
+
+  install -Dm644 LICENSE "${pkgdir}${MINGW_PREFIX}/share/licenses/python2-${_realname}/LICENSE"
+}
+
+package_mingw-w64-i686-python2-funcsigs() {
+  package_python2-funcsigs
+}
+
+package_mingw-w64-i686-python3-funcsigs() {
+  package_python3-funcsigs
+}
+
+package_mingw-w64-x86_64-python2-funcsigs() {
+  package_python2-funcsigs
+}
+
+package_mingw-w64-x86_64-python3-funcsigs() {
+  package_python3-funcsigs
+}