From 4db1b7cb9196d1a199f4201ede366fa3568db8cc Mon Sep 17 00:00:00 2001
From: Biswa96 <nathbappai@gmail.com>
Date: Wed, 1 Jul 2020 19:16:06 +0530
Subject: [PATCH] simdjson: add package

---
 mingw-w64-simdjson/PKGBUILD | 44 +++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)
 create mode 100644 mingw-w64-simdjson/PKGBUILD

diff --git a/mingw-w64-simdjson/PKGBUILD b/mingw-w64-simdjson/PKGBUILD
new file mode 100644
index 0000000000..32ab8dc3e7
--- /dev/null
+++ b/mingw-w64-simdjson/PKGBUILD
@@ -0,0 +1,44 @@
+# Maintainer: Alexey Pavlov <alexpux@gmail.com>
+
+_realname=simdjson
+pkgbase=mingw-w64-${_realname}
+pkgname="${MINGW_PACKAGE_PREFIX}-${_realname}"
+pkgver=0.4.5
+pkgrel=1
+pkgdesc="A C++ library to see how fast we can parse JSON with complete validation (mingw-w64)"
+arch=('any')
+url="https://github.com/lemire/simdjson"
+license=('Apache-2.0')
+depends=("${MINGW_PACKAGE_PREFIX}-gcc-libs")
+makedepends=("${MINGW_PACKAGE_PREFIX}-cmake"
+             "${MINGW_PACKAGE_PREFIX}-ninja")
+source=("${_realname}-${pkgver}.tar.gz::https://github.com/lemire/simdjson/archive/v${pkgver}.tar.gz")
+sha512sums=('97a858378d4e3d4fcf834851d3388119c343506ad0c1b9bd3e8f6f74ad342893553f5e1ef7d5c764e3b508caada94e9c8d4dd087058aff9e759753ebe14b2c1d')
+
+build() {
+  [[ -d ${srcdir}/build-${MINGW_CHOST} ]] && rm -rf ${srcdir}/build-${MINGW_CHOST}
+  mkdir -p build-${MINGW_CHOST} && cd build-${MINGW_CHOST}
+
+  MSYS2_ARG_CONV_EXCL="-DCMAKE_INSTALL_PREFIX=" \
+  ${MINGW_PREFIX}/bin/cmake \
+    -G Ninja \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DCMAKE_INSTALL_PREFIX=${MINGW_PREFIX} \
+    -DSIMDJSON_JUST_LIBRARY=ON \
+    ../${_realname}-${pkgver}
+
+  ${MINGW_PREFIX}/bin/cmake --build ./
+}
+
+check() {
+  cd ${srcdir}/build-${MINGW_CHOST}
+  ${MINGW_PREFIX}/bin/ctest ./
+}
+
+package() {
+  cd ${srcdir}/build-${MINGW_CHOST}
+  DESTDIR="${pkgdir}" ${MINGW_PREFIX}/bin/cmake --build ./ --target install
+
+  install -Dm644 ${srcdir}/${_realname}-${pkgver}/README.md ${pkgdir}${MINGW_PREFIX}/share/doc/${_realname}/README.md
+  install -Dm644 ${srcdir}/${_realname}-${pkgver}/LICENSE ${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/LICENSE
+}