From 5572519cf143de0caf71fb3c8967e8417841a2c4 Mon Sep 17 00:00:00 2001
From: Konstantin Podsvirov <konstantin@podsvirov.pro>
Date: Fri, 19 Dec 2025 18:44:03 +0300
Subject: [PATCH] [new package] wgsl-analyzer 20251114 (#26897)

---
 mingw-w64-wgsl-analyzer/PKGBUILD | 53 ++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)
 create mode 100644 mingw-w64-wgsl-analyzer/PKGBUILD

diff --git a/mingw-w64-wgsl-analyzer/PKGBUILD b/mingw-w64-wgsl-analyzer/PKGBUILD
new file mode 100644
index 0000000000..7a2740c043
--- /dev/null
+++ b/mingw-w64-wgsl-analyzer/PKGBUILD
@@ -0,0 +1,53 @@
+# Maintainer: Konstantin Podsvirov <konstantin@podsvirov.su>
+
+_realname=wgsl-analyzer
+pkgbase=mingw-w64-${_realname}
+pkgname=("${MINGW_PACKAGE_PREFIX}-${_realname}")
+_pkgver=2025-11-14
+pkgver=${_pkgver//-}
+pkgrel=1
+pkgdesc="A language server implementation for WGSL and WESL (mingw-w64)"
+arch=('any')
+mingw_arch=('ucrt64' 'clang64' 'clangarm64')
+url='https://wgsl-analyzer.github.io/'
+msys2_repository_url='https://github.com/wgsl-analyzer/wgsl-analyzer'
+license=('spdx:MIT OR Apache-2.0')
+makedepends=("${MINGW_PACKAGE_PREFIX}-rust"
+             'git')
+source=("${msys2_repository_url}/archive/${_pkgver}/${_realname}-${_pkgver}.tar.gz")
+sha256sums=('f0c93d63c6795d136a6e8bd75f1ae6d53f9204b3f830d9999faf75c0c88e8b2e')
+
+prepare() {
+  cd "${_realname}-${_pkgver}"
+
+  cargo fetch \
+    --locked \
+    --config='net.git-fetch-with-cli=true' \
+    --target "${RUST_CHOST}"
+}
+
+build() {
+  cd "${_realname}-${_pkgver}"
+
+  cargo build --release --frozen -p ${_realname}
+}
+
+check() {
+  cd "${_realname}-${_pkgver}"
+
+  cargo test --release --frozen -p ${_realname}
+}
+
+package() {
+  cd "${_realname}-${_pkgver}"
+
+  cargo install \
+    --offline \
+    --no-track \
+    --frozen \
+    --path "./crates/${_realname}" \
+    --root "${pkgdir}${MINGW_PREFIX}"
+
+  install -Dm644 LICENSE-APACHE "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/LICENSE-APACHE"
+  install -Dm644 LICENSE-MIT "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/LICENSE-MIT"
+}