diff --git a/mingw-w64-python-sphinx-copybutton/PKGBUILD b/mingw-w64-python-sphinx-copybutton/PKGBUILD
new file mode 100644
index 0000000000..6ac8ed0e21
--- /dev/null
+++ b/mingw-w64-python-sphinx-copybutton/PKGBUILD
@@ -0,0 +1,37 @@
+# Maintainer: Konstantin Podsvirov <konstantin@podsvirov.pro>
+
+_realname=sphinx-copybutton
+pkgname=("${MINGW_PACKAGE_PREFIX}-python-$_realname")
+pkgver=0.5.0
+pkgrel=1
+pkgdesc="Sphinx extension to add a \"copy\" button to code blocks (mingw-w64)"
+arch=('any')
+mingw_arch=('mingw32' 'mingw64' 'ucrt64' 'clang64' 'clang32' 'clangarm64')
+url="https://sphinx-copybutton.readthedocs.io/"
+license=('MIT')
+depends=("${MINGW_PACKAGE_PREFIX}-python-sphinx")
+makedepends=("${MINGW_PACKAGE_PREFIX}-python-setuptools")
+source=(https://files.pythonhosted.org/packages/source/s/$_realname/$_realname-$pkgver.tar.gz)
+sha256sums=('a0c059daadd03c27ba750da534a92a63e7a36a7736dcf684f26ee346199787f6')
+
+prepare() {
+  cd "${srcdir}"
+  cp -r "${_realname}-${pkgver}" "python-build-${MSYSTEM}"
+}
+
+build() {
+  cd "${srcdir}/python-build-${MSYSTEM}"
+  ${MINGW_PREFIX}/bin/python setup.py build
+}
+
+package() {
+  cd "${srcdir}/python-build-${MSYSTEM}"
+  MSYS2_ARG_CONV_EXCL="--prefix=;--install-scripts=;--install-platlib=" \
+  "${MINGW_PREFIX}"/bin/python setup.py install -O1 --skip-build \
+      --root="${pkgdir}" --prefix="${MINGW_PREFIX}"
+
+  install -Dm644 LICENSE "${pkgdir}${MINGW_PREFIX}/share/licenses/python-${_realname}/LICENSE"
+  install -Dm644 README.md "${pkgdir}${MINGW_PREFIX}/share/doc/python-${_realname}/README.md"
+}
+
+# vim:set ts=2 sw=2 et: