From 670c3c49e1da52bebc55ea776dd90e29346b8cb5 Mon Sep 17 00:00:00 2001
From: Andrea Zagli <azagli@libero.it>
Date: Mon, 18 Jul 2016 10:42:12 +0200
Subject: [PATCH] libvirt-glib: new package.

---
 mingw-w64-libvirt-glib/001-win.patch | 22 ++++++++++
 mingw-w64-libvirt-glib/PKGBUILD      | 62 ++++++++++++++++++++++++++++
 2 files changed, 84 insertions(+)
 create mode 100644 mingw-w64-libvirt-glib/001-win.patch
 create mode 100644 mingw-w64-libvirt-glib/PKGBUILD

diff --git a/mingw-w64-libvirt-glib/001-win.patch b/mingw-w64-libvirt-glib/001-win.patch
new file mode 100644
index 0000000000..2fe88e6b93
--- /dev/null
+++ b/mingw-w64-libvirt-glib/001-win.patch
@@ -0,0 +1,22 @@
+--- ./libvirt-gobject/Makefile.am.orig	2016-07-18 10:03:46.534356500 +0200
++++ ./libvirt-gobject/Makefile.am	2016-07-18 10:06:01.550863500 +0200
+@@ -94,7 +94,8 @@
+ 			$(COVERAGE_CFLAGS:-f%=-Wc,f%) \
+ 			$(CYGWIN_EXTRA_LDFLAGS) $(MINGW_EXTRA_LDFLAGS) \
+ 			-Wl,--version-script=$(srcdir)/libvirt-gobject.sym \
+-			-version-info $(LIBVIRT_GLIB_VERSION_INFO)
++			-version-info $(LIBVIRT_GLIB_VERSION_INFO) \
++			-no-undefined
+ 
+ libvirt-gobject-enums.c: $(libvirt_gobject_1_0_la_HEADERS)
+ 	$(AM_V_GEN)glib-mkenums \
+--- ./python/Makefile.am.orig	2016-07-18 10:09:19.492771200 +0200
++++ ./python/Makefile.am	2016-07-18 10:09:31.617963900 +0200
+@@ -16,6 +16,7 @@
+ libvirtglibmod_la_CFLAGS = -Wno-redundant-decls
+ 
+ libvirtglibmod_la_LDFLAGS = -module -avoid-version \
++    -no-undefined \
+ 	$(CYGWIN_EXTRA_LDFLAGS)
+ libvirtglibmod_la_LIBADD = ../libvirt-glib/libvirt-glib-1.0.la
+ 	$(CYGWIN_EXTRA_LIBADD) $(CYGWIN_EXTRA_PYTHON_LIBADD)
diff --git a/mingw-w64-libvirt-glib/PKGBUILD b/mingw-w64-libvirt-glib/PKGBUILD
new file mode 100644
index 0000000000..72ccd2beb8
--- /dev/null
+++ b/mingw-w64-libvirt-glib/PKGBUILD
@@ -0,0 +1,62 @@
+# Maintainer: Andrea Zagli <andrea.zagli.free@gmail.com>
+
+_realname=libvirt-glib
+pkgbase=mingw-w64-${_realname}
+pkgname="${MINGW_PACKAGE_PREFIX}-${_realname}"
+pkgver=0.2.3
+pkgrel=1
+arch=('any')
+pkgdesc="libvirt GLib and GObject mapping library (mingw-w64)"
+depends=("${MINGW_PACKAGE_PREFIX}-glib2"
+         "${MINGW_PACKAGE_PREFIX}-libxml2"
+         "${MINGW_PACKAGE_PREFIX}-libvirt")
+makedepends=("${MINGW_PACKAGE_PREFIX}-gcc"
+             "gtk-doc"
+             "${MINGW_PACKAGE_PREFIX}-vala"
+             "${MINGW_PACKAGE_PREFIX}-gobject-introspection"
+             "${MINGW_PACKAGE_PREFIX}-pkg-config")
+options=('!strip' 'debug' 'staticlibs')
+license=("LGPL 2.1")
+url="http://www.gnome.org/"
+#install=${_realname}-${CARCH}.install
+source=(http://libvirt.org/sources/glib/${_realname}-${pkgver}.tar.gz
+        001-win.patch)
+sha256sums=('c3b11aa34584b3416148b36bb005505e461830c73c9fd2f40143cca3309250dd'
+            '8e01a16596e46c4d9bf5ecc1e27f07bfdaba1fa356ac3cae31d5135e4f10ea4a')
+
+prepare() {
+  cd ${_realname}-${pkgver}
+
+  patch -p1 -i ${srcdir}/001-win.patch
+
+  autoreconf -fi
+}
+
+build() {
+  [[ -d build-${MINGW_CHOST} ]] && rm -rf build-${MINGW_CHOST}
+  mkdir -p build-${MINGW_CHOST}
+  cd build-${MINGW_CHOST}
+
+  mkdir -p docs/libvirt-gconfig/html
+  cp -rf ../${_realname}-${pkgver}/docs/libvirt-gconfig/html/* docs/libvirt-gconfig/html
+  mkdir -p docs/libvirt-glib/html
+  cp -rf ../${_realname}-${pkgver}/docs/libvirt-glib/html/* docs/libvirt-glib/html
+  mkdir -p docs/libvirt-gobject/html
+  cp -rf ../${_realname}-${pkgver}/docs/libvirt-gobject/html/* docs/libvirt-gobject/html
+
+  ../${_realname}-${pkgver}/configure \
+    --host=${MINGW_CHOST} \
+    --target=${MINGW_CHOST} \
+    --build=${MINGW_CHOST} \
+    --prefix=${MINGW_PREFIX} \
+    --libexecdir=${MINGW_PREFIX}/lib \
+    --without-python
+  make
+}
+
+package() {
+  cd "$srcdir/build-${MINGW_CHOST}"
+  make DESTDIR=$pkgdir install
+
+  install -Dm644 "${srcdir}/${_realname}-${pkgver}/COPYING" "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/COPYING"
+}