From 67b7bfb7341d1a2eb4a9844f0ffcdfb7ec5e69bc Mon Sep 17 00:00:00 2001
From: Maksim Bondarenkov <119937608+ognevny@users.noreply.github.com>
Date: Sat, 27 Jul 2024 10:39:32 +0300
Subject: [PATCH] [new package] sad 0.4.31

---
 mingw-w64-sad/PKGBUILD | 48 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)
 create mode 100644 mingw-w64-sad/PKGBUILD

diff --git a/mingw-w64-sad/PKGBUILD b/mingw-w64-sad/PKGBUILD
new file mode 100644
index 0000000000..d66d253c58
--- /dev/null
+++ b/mingw-w64-sad/PKGBUILD
@@ -0,0 +1,48 @@
+# Maintainer: Maksim Bondarenkov <maksapple2306@gmail.com>
+
+_realname=sad
+pkgbase=mingw-w64-${_realname}
+pkgname="${MINGW_PACKAGE_PREFIX}-${_realname}"
+pkgver=0.4.31
+pkgrel=1
+pkgdesc="Space Age seD (mingw-w64)"
+arch=('any')
+mingw_arch=('ucrt64' 'clang64')
+url='https://github.com/ms-jpq/sad'
+license=('spdx:MIT')
+makedepends=("${MINGW_PACKAGE_PREFIX}-rust" "${MINGW_PACKAGE_PREFIX}-python")
+optdepends=("${MINGW_PACKAGE_PREFIX}-fzf: for tui usage"
+            "${MINGW_PACKAGE_PREFIX}-delta: for diff colourizer")
+source=("${url}/archive/v${pkgver}/${_realname}-${pkgver}.tar.gz")
+sha256sums=('c717e54798e21356340271e32e43de5b05ba064ae64edf639fede27b1ed15ceb')
+
+prepare() {
+  cd "${_realname}-${pkgver}"
+
+  cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
+}
+
+build() {
+  cd "${_realname}-${pkgver}"
+
+  cargo build --release --frozen
+}
+
+check() {
+  cd "${srcdir}/${_realname}-${pkgver}"
+
+  cargo test --release --frozen
+}
+
+package() {
+  cd "${_realname}-${pkgver}"
+
+  cargo install \
+    --offline \
+    --no-track \
+    --frozen \
+    --path . \
+    --root "${pkgdir}${MINGW_PREFIX}"
+
+  install -Dm644 LICENSE "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/LICENSE"
+}