diff --git a/mingw-w64-gtksourceview5/001-missing-include.patch b/mingw-w64-gtksourceview5/001-missing-include.patch
new file mode 100644
index 0000000000..c5e66eeff1
--- /dev/null
+++ b/mingw-w64-gtksourceview5/001-missing-include.patch
@@ -0,0 +1,10 @@
+--- gtksourceview-5.0.0/gtksourceview/gtksourcesnippetbundle-parser.c.orig	2021-07-10 14:07:51.916000000 +0200
++++ gtksourceview-5.0.0/gtksourceview/gtksourcesnippetbundle-parser.c	2021-07-10 14:07:57.199228300 +0200
+@@ -20,6 +20,7 @@
+ #include "config.h"
+ 
+ #include <errno.h>
++#include <stdlib.h>
+ 
+ #include "gtksourcesnippetbundle-private.h"
+ #include "gtksourcesnippetchunk.h"
diff --git a/mingw-w64-gtksourceview5/PKGBUILD b/mingw-w64-gtksourceview5/PKGBUILD
new file mode 100644
index 0000000000..cb7f850bdd
--- /dev/null
+++ b/mingw-w64-gtksourceview5/PKGBUILD
@@ -0,0 +1,50 @@
+# Maintainer: Taozuhong <taozuhong@gmail.com>
+
+_realname=gtksourceview
+pkgbase=mingw-w64-${_realname}5
+pkgname="${MINGW_PACKAGE_PREFIX}-${_realname}5"
+pkgver=5.0.0
+pkgrel=1
+pkgdesc="A text widget adding syntax highlighting and more to GNOME (mingw-w64)"
+arch=('any')
+mingw_arch=('any')
+url="https://www.gnome.org"
+license=("LGPL")
+makedepends=("${MINGW_PACKAGE_PREFIX}-vala"
+             "${MINGW_PACKAGE_PREFIX}-pkg-config"
+             "${MINGW_PACKAGE_PREFIX}-gobject-introspection"
+             "${MINGW_PACKAGE_PREFIX}-meson")
+depends=("${MINGW_PACKAGE_PREFIX}-gtk4"
+         "${MINGW_PACKAGE_PREFIX}-libxml2"
+         "${MINGW_PACKAGE_PREFIX}-pcre2"
+         "${MINGW_PACKAGE_PREFIX}-fribidi")
+source=("https://download.gnome.org/sources/gtksourceview/${pkgver:0:3}/gtksourceview-${pkgver}.tar.xz"
+        "001-missing-include.patch")
+sha256sums=('64826633c0c8d2c6a6eb4ec653215ef04e31e13a2d4156a09ca5fd9013acd9c3'
+            'e56e7c04b5731b5a89abd02aaf383a359aa72cf1535032f74dae7caacd00b526')
+
+prepare() {
+  cd "${srcdir}/${_realname}-${pkgver}"
+
+  patch -Np1 -i "${srcdir}/001-missing-include.patch"
+}
+
+build() {
+  [[ -d "${srcdir}/build-${MINGW_CHOST}" ]] && rm -rf "${srcdir}/build-${MINGW_CHOST}"
+  mkdir -p "${srcdir}/build-${MINGW_CHOST}" && cd "${srcdir}/build-${MINGW_CHOST}"
+
+  MSYS2_ARG_CONV_EXCL="--prefix=" \
+  ${MINGW_PREFIX}/bin/meson.exe \
+    --prefix="${MINGW_PREFIX}" \
+    --buildtype=plain \
+    "../${_realname}-${pkgver}"
+
+  ${MINGW_PREFIX}/bin/meson.exe compile
+}
+
+package() {
+  cd "${srcdir}/build-${MINGW_CHOST}"
+  DESTDIR="${pkgdir}" ${MINGW_PREFIX}/bin/meson.exe install
+
+  install -Dm644 "${srcdir}/${_realname}-${pkgver}/COPYING" "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}5/COPYING"
+}