diff --git a/mingw-w64-python-typing-inspection/PKGBUILD b/mingw-w64-python-typing-inspection/PKGBUILD
new file mode 100644
index 0000000000..5a2bbc62d6
--- /dev/null
+++ b/mingw-w64-python-typing-inspection/PKGBUILD
@@ -0,0 +1,38 @@
+# Maintainer: Biswapriyo Nath <nathbappai@gmail.com>
+
+_realname=typing-inspection
+pkgbase=mingw-w64-python-${_realname}
+pkgname=("${MINGW_PACKAGE_PREFIX}-python-${_realname}")
+pkgver=0.4.0
+pkgrel=1
+pkgdesc="Runtime typing introspection tools (mingw-w64)"
+arch=('any')
+mingw_arch=('mingw64' 'ucrt64' 'clang64' 'clangarm64')
+msys2_references=(
+  'purl: pkg:pypi/typing-inspection'
+)
+msys2_repository_url='https://github.com/pydantic/typing-inspection'
+url='https://typing-inspection.pydantic.dev/'
+license=('spdx:MIT')
+depends=("${MINGW_PACKAGE_PREFIX}-python"
+         "${MINGW_PACKAGE_PREFIX}-python-typing_extensions")
+makedepends=("${MINGW_PACKAGE_PREFIX}-python-build"
+             "${MINGW_PACKAGE_PREFIX}-python-installer"
+             "${MINGW_PACKAGE_PREFIX}-python-hatchling")
+source=("https://pypi.org/packages/source/${_realname::1}/${_realname/-/_}/${_realname/-/_}-${pkgver}.tar.gz")
+sha256sums=('9765c87de36671694a67904bf2c96e395be9c6439bb6c87b5142569dcdd65122')
+
+build() {
+  cp -r "${_realname/-/_}-${pkgver}" "python-build-${MSYSTEM}" && cd "python-build-${MSYSTEM}"
+  python -m build --wheel --skip-dependency-check --no-isolation
+}
+
+package() {
+  cd "python-build-${MSYSTEM}"
+
+  MSYS2_ARG_CONV_EXCL="--prefix=" \
+    python -m installer --prefix=${MINGW_PREFIX} \
+    --destdir="${pkgdir}" dist/*.whl
+
+  install -Dm644 LICENSE "${pkgdir}${MINGW_PREFIX}/share/licenses/python-${_realname}/LICENSE"
+}