diff --git a/mingw-w64-python-google-auth-httplib2/PKGBUILD b/mingw-w64-python-google-auth-httplib2/PKGBUILD
new file mode 100644
index 0000000000..1d4221e97a
--- /dev/null
+++ b/mingw-w64-python-google-auth-httplib2/PKGBUILD
@@ -0,0 +1,49 @@
+# Maintainer: Biswapriyo Nath <nathbappai@gmail.com>
+
+_realname=google-auth-httplib2
+pkgbase=mingw-w64-python-${_realname}
+pkgname=("${MINGW_PACKAGE_PREFIX}-python-${_realname}")
+pkgver=0.2.0
+pkgrel=1
+pkgdesc="Google Authentication Library: httplib2 transport (mingw-w64)"
+arch=('any')
+mingw_arch=('mingw64' 'ucrt64' 'clang64' 'clangarm64')
+msys2_references=(
+  'archlinux: python-google-auth-httplib2'
+  'pypi: google-auth-httplib2'
+)
+url='https://github.com/googleapis/google-auth-library-python-httplib2'
+license=('spdx:Apache-2.0')
+depends=(
+  "${MINGW_PACKAGE_PREFIX}-python"
+  "${MINGW_PACKAGE_PREFIX}-python-google-auth"
+  "${MINGW_PACKAGE_PREFIX}-python-httplib2"
+)
+makedepends=(
+  "${MINGW_PACKAGE_PREFIX}-python-build"
+  "${MINGW_PACKAGE_PREFIX}-python-installer"
+  "${MINGW_PACKAGE_PREFIX}-python-setuptools"
+)
+checkdepends=("${MINGW_PACKAGE_PREFIX}-python-pytest")
+source=("https://pypi.org/packages/source/${_realname::1}/${_realname}/${_realname}-${pkgver}.tar.gz")
+sha256sums=('38aa7badf48f974f1eb9861794e9c0cb2a0511a4ec0679b1f886d108f5640e05')
+
+build() {
+  cp -r "${_realname}-${pkgver}" "python-build-${MSYSTEM}" && cd "python-build-${MSYSTEM}"
+  python -m build --wheel --skip-dependency-check --no-isolation
+}
+
+check() {
+  cd "python-build-${MSYSTEM}"
+  python -m pytest || warning "Tests failed"
+}
+
+package() {
+  cd "python-build-${MSYSTEM}"
+
+  MSYS2_ARG_CONV_EXCL="--prefix=" \
+    python -m installer --prefix=${MINGW_PREFIX} \
+    --destdir="${pkgdir}" dist/*.whl
+
+  install -Dm644 LICENSE "${pkgdir}${MINGW_PREFIX}/share/licenses/python-${_realname}/LICENSE"
+}