python_ics: New package

mingw-w64-python-python_ics/PKGBUILD

@@ -0,0 +1,77 @@
+# Maintainer: Alexey Pavlov <alexpux@gmail.com>
+
+_realname=python_ics
+pkgbase=mingw-w64-python-${_realname}
+pkgname=("${MINGW_PACKAGE_PREFIX}-python2-${_realname}" "${MINGW_PACKAGE_PREFIX}-python3-${_realname}")
+pkgver=2.15
+pkgrel=1
+pkgdesc="Python C Code module for interfacing to the icsneo40 dynamic library (mingw-w64)"
+arch=('any')
+url='https://github.com/intrepidcs/python_ics/'
+license=('MIT')
+makedepends=("${MINGW_PACKAGE_PREFIX}-python2"
+             "${MINGW_PACKAGE_PREFIX}-python3"
+             "${MINGW_PACKAGE_PREFIX}-python3-setuptools"
+             "${MINGW_PACKAGE_PREFIX}-python2-setuptools")
+options=('staticlibs' 'strip' '!debug')
+source=("${_realname}-${pkgver}.tar.gz"::"https://github.com/intrepidcs/python_ics/archive/${pkgver}.tar.gz"
+        mingw-build.patch)
+sha512sums=('70e1963b44d3d14c365694d118a9af890db8e53851c7b2726d92f10bf2e417d02e5c0c7fdaa9230a8e063538dea12884c46ca549bff7722246f6f2e0b12cfd55'
+            '210af98775409f442d7b20d55098579854997fdecdae5c96ba7f290b04a8b2c237e928c881d4a6adca5f46f280652dba852213b72322a0e4002ea968b0516017')
+
+prepare() {
+  cd ${_realname}-${pkgver}
+  patch -p1 -i ${srcdir}/mingw-build.patch
+
+  cd "${srcdir}"
+  for builddir in python{2,3}-build-${CARCH}; do
+    rm -rf ${builddir} | true
+    cp -r "${_realname}-${pkgver}" "${builddir}"
+  done
+}
+
+build() {
+  for pver in {2,3}; do  
+    msg "Python ${pver} build for ${CARCH}"  
+    cd "${srcdir}/python${pver}-build-${CARCH}"
+    ${MINGW_PREFIX}/bin/python${pver} setup.py build
+  done  
+}
+
+package_python3-python_ics() {
+  depends=("${MINGW_PACKAGE_PREFIX}-python3")
+
+  cd "${srcdir}/python3-build-${CARCH}"
+  MSYS2_ARG_CONV_EXCL="--prefix=;--install-scripts=;--install-platlib=" \
+  ${MINGW_PREFIX}/bin/python3 setup.py install --prefix=${MINGW_PREFIX} \
+    --root="${pkgdir}" --optimize=1 --skip-build
+
+  #install -Dm644 LICENSE.txt "${pkgdir}${MINGW_PREFIX}/share/licenses/python3-${_realname}/LICENSE.txt"
+}
+
+package_python2-python_ics() {
+  depends=("${MINGW_PACKAGE_PREFIX}-python2")
+
+  cd "${srcdir}/python2-build-${CARCH}"
+  MSYS2_ARG_CONV_EXCL="--prefix=;--install-scripts=;--install-platlib=" \
+  ${MINGW_PREFIX}/bin/python2 setup.py install --prefix=${MINGW_PREFIX} \
+    --root="${pkgdir}" --optimize=1 --skip-build
+
+  #install -Dm644 LICENSE.txt "${pkgdir}${MINGW_PREFIX}/share/licenses/python2-${_realname}/LICENSE.txt"
+}
+
+package_mingw-w64-i686-python2-python_ics() {
+  package_python2-python_ics
+}
+
+package_mingw-w64-i686-python3-python_ics() {
+  package_python3-python_ics
+}
+
+package_mingw-w64-x86_64-python2-python_ics() {
+  package_python2-python_ics
+}
+
+package_mingw-w64-x86_64-python3-python_ics() {
+  package_python3-python_ics
+}