From a95ca2ee84d6d35b486f92a64bc34237fb3dee83 Mon Sep 17 00:00:00 2001
From: Ryuta Suzuki <oroppas@gmail.com>
Date: Tue, 5 Apr 2016 11:25:45 +0900
Subject: [PATCH] python-decorator: Created PKGBUILD

---
 mingw-w64-python-decorator/PKGBUILD | 73 +++++++++++++++++++++++++++++
 1 file changed, 73 insertions(+)
 create mode 100644 mingw-w64-python-decorator/PKGBUILD

diff --git a/mingw-w64-python-decorator/PKGBUILD b/mingw-w64-python-decorator/PKGBUILD
new file mode 100644
index 0000000000..f9df6d496a
--- /dev/null
+++ b/mingw-w64-python-decorator/PKGBUILD
@@ -0,0 +1,73 @@
+# Maintainer: Ryuta Suzuki <oroppas@gmail.com>
+
+_realname=decorator
+pkgbase=mingw-w64-python-${_realname}
+pkgname=(
+  "${MINGW_PACKAGE_PREFIX}-python3-${_realname}"
+  "${MINGW_PACKAGE_PREFIX}-python2-${_realname}"
+)
+pkgver=4.0.9
+pkgrel=1
+pkgdesc="Better living through Python with decorators (mingw-w64)"
+arch=('any')
+license=('BSD')
+url="http://github.com/micheles/decorator"
+makedepends=(
+  "${MINGW_PACKAGE_PREFIX}-python3-setuptools"
+  "${MINGW_PACKAGE_PREFIX}-python2-setuptools"
+  'git'
+)
+source=("git+https://github.com/micheles/${_realname}.git#branch=$pkgver")
+sha512sums=('SKIP')
+
+prepare() {
+  cp -a ${_realname}{,-py2}
+}
+
+build() {
+  cd ${srcdir}/${_realname}
+  python3 setup.py build
+
+  cd ${srcdir}/${_realname}-py2
+  python2 setup.py build
+}
+
+package_python3-decorator() {
+  depends=(
+    "${MINGW_PACKAGE_PREFIX}-python3"
+  )
+
+  cd ${_realname}
+  MSYS2_ARG_CONV_EXCL="--prefix=;--install-scripts=;--install-platlib=" \
+  ${MINGW_PREFIX}/bin/python3 setup.py install --root=${pkgdir} --prefix=${MINGW_PREFIX} --optimize=1
+  install -D -m644 LICENSE.txt ${pkgdir}/${MINGW_PREFIX}/share/licenses/python3-${_realname}/LICENSE
+}
+
+package_python2-decorator() {
+  depends=(
+    "${MINGW_PACKAGE_PREFIX}-python2"
+  )
+
+  cd ${_realname}-py2
+  MSYS2_ARG_CONV_EXCL="--prefix=;--install-scripts=;--install-platlib=" \
+  ${MINGW_PREFIX}/bin/python2 setup.py install --root=${pkgdir} --prefix=${MINGW_PREFIX} --optimize=1
+  install -D -m644 LICENSE.txt ${pkgdir}/${MINGW_PREFIX}/share/licenses/python2-${_realname}/LICENSE
+}
+
+package_mingw-w64-i686-python2-decorator() {
+  package_python2-decorator
+}
+
+package_mingw-w64-i686-python3-decorator() {
+  package_python3-decorator
+}
+
+package_mingw-w64-x86_64-python2-decorator() {
+  package_python2-decorator
+}
+
+package_mingw-w64-x86_64-python3-decorator() {
+  package_python3-decorator
+}
+
+# vim:set ts=2 sw=2 et: