From aad19731f9e65c96f21392279bba2ffc45fa8b0f Mon Sep 17 00:00:00 2001
From: Alexpux <alexey.pawlow@gmail.com>
Date: Wed, 5 Mar 2014 11:53:27 +0400
Subject: [PATCH] Add python-reportlab packages.

---
 mingw-w64-python-reportlab/PKGBUILD | 76 +++++++++++++++++++++++++++++
 1 file changed, 76 insertions(+)
 create mode 100644 mingw-w64-python-reportlab/PKGBUILD

diff --git a/mingw-w64-python-reportlab/PKGBUILD b/mingw-w64-python-reportlab/PKGBUILD
new file mode 100644
index 0000000000..bd7c00b6aa
--- /dev/null
+++ b/mingw-w64-python-reportlab/PKGBUILD
@@ -0,0 +1,76 @@
+# Maintainer: Alexey Pavlov <alexpux@gmail.com>
+# Contributor: Ray Donnelly <mingw.android@gmail.com>
+
+_realname=reportlab
+_mingw_suff=mingw-w64-${CARCH}
+pkgname="${_mingw_suff}-${_realname}"
+pkgname=("${_mingw_suff}-python2-${_realname}" "${_mingw_suff}-python3-${_realname}")
+pkgver=3.0
+pkgrel=1
+pkgdesc="A proven industry-strength PDF generating solution (mingw-w64)"
+arch=('any')
+license=('custom')
+url="http://www.reportlab.org/rl_toolkit.html"
+depends=("${_mingw_suff}-freetype")
+makedepends=("${_mingw_suff}-python2"
+		"${_mingw_suff}-python3")
+source=(http://www.reportlab.com/ftp/${_realname}-${pkgver}.tar.gz)
+md5sums=('a4fd40abcfb604aa3bd907181133c071')
+ 
+prepare() {
+	cd "${srcdir}/${_realname}-${pkgver}"
+
+	cd "${srcdir}"
+	cp -r ${_realname}-${pkgver} build-python2
+	cp -r ${_realname}-${pkgver} build-python3
+}
+
+build() {
+	export FT_LIB=${MINGW_PREFIX}/lib/libfreetype.a
+	export FT_INC=${MINGW_PREFIX}/include/freetype2
+	# Build python 2 module
+	cd "${srcdir}"/build-python2
+	${MINGW_PREFIX}/bin/python2 setup.py build
+
+	# Build python 3 module
+	cd "${srcdir}"/build-python3
+	${MINGW_PREFIX}/bin/python3 setup.py build
+}
+
+package_python2-reportlab() {
+	depends=("${_mingw_suff}-python2")
+
+	cd "${srcdir}/build-python2"
+	MSYS2_ARG_CONV_EXCL="--prefix=;--install-scripts=;--install-platlib=" \
+		${MINGW_PREFIX}/bin/python2 setup.py install --prefix=${MINGW_PREFIX#\/} --root="${pkgdir}" --optimize=1 --skip-build
+
+	install -Dm644 LICENSE.txt \
+		"${pkgdir}${MINGW_PREFIX}"/share/licenses/python2-${_realname}/LICENSE
+}
+
+package_python3-reportlab() {
+	depends=("${_mingw_suff}-python3")
+
+	cd "${srcdir}/build-python3"
+	MSYS2_ARG_CONV_EXCL="--prefix=;--install-scripts=;--install-platlib=" \
+		${MINGW_PREFIX}/bin/python3 setup.py install --prefix=${MINGW_PREFIX#\/} --root="${pkgdir}" --optimize=1 --skip-build
+
+	install -Dm644 LICENSE.txt \
+		"${pkgdir}${MINGW_PREFIX}"/share/licenses/python3-${_realname}/LICENSE
+}
+
+package_mingw-w64-i686-python2-reportlab() {
+	package_python2-reportlab
+}
+
+package_mingw-w64-i686-python3-reportlab() {
+	package_python3-reportlab
+}
+
+package_mingw-w64-x86_64-python2-reportlab() {
+	package_python2-reportlab
+}
+
+package_mingw-w64-x86_64-python3-reportlab() {
+	package_python3-reportlab
+}