From e175fed4c1a199807847ae1692f9b6b46e071040 Mon Sep 17 00:00:00 2001
From: Konstantin Podsvirov <konstantin@podsvirov.pro>
Date: Mon, 25 Sep 2023 22:45:09 +0300
Subject: [PATCH] sqlite-orm: New package

---
 mingw-w64-sqlite-orm/PKGBUILD | 45 +++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)
 create mode 100644 mingw-w64-sqlite-orm/PKGBUILD

diff --git a/mingw-w64-sqlite-orm/PKGBUILD b/mingw-w64-sqlite-orm/PKGBUILD
new file mode 100644
index 0000000000..a25dc31e9d
--- /dev/null
+++ b/mingw-w64-sqlite-orm/PKGBUILD
@@ -0,0 +1,45 @@
+# Maintainer: Konstantin Podsvirov <konstantin@podsvirov.pro>
+
+_realname=sqlite-orm
+pkgbase=mingw-w64-${_realname}
+pkgname=("${MINGW_PACKAGE_PREFIX}-${_realname}")
+pkgver=1.8.2
+pkgrel=1
+pkgdesc="SQLite ORM light header only library for modern C++ (mingw-w64)"
+arch=('any')
+mingw_arch=('mingw32' 'mingw64' 'ucrt64' 'clang64' 'clangarm64' 'clang32')
+url="https://github.com/fnc12/sqlite_orm"
+license=('AGPL3')
+makedepends=("${MINGW_PACKAGE_PREFIX}-cc"
+             "${MINGW_PACKAGE_PREFIX}-cmake"
+             "${MINGW_PACKAGE_PREFIX}-ninja")
+depends=("${MINGW_PACKAGE_PREFIX}-sqlite3")
+source=("${_realname/-/_}-${pkgver}.tar.gz::${url}/archive/v${pkgver}.tar.gz")
+sha256sums=('56e0c7729800637a8061658d0fdad4424d2cdde77b063d23cc1b76aa20339072')
+
+build() {
+  [[ -d "${srcdir}/build-${MSYSTEM}" ]] && rm -rf "${srcdir}/build-${MSYSTEM}"
+  mkdir -p "${srcdir}/build-${MSYSTEM}" && cd "${srcdir}/build-${MSYSTEM}"
+
+  MSYS2_ARG_CONV_EXCL="-DCMAKE_INSTALL_PREFIX=" \
+  ${MINGW_PREFIX}/bin/cmake.exe \
+    -GNinja \
+    -DCMAKE_INSTALL_PREFIX=${MINGW_PREFIX} \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DBUILD_TESTING=OFF \
+    -DBUILD_EXAMPLES=OFF \
+    ../${_realname/-/_}-${pkgver}
+
+  ${MINGW_PREFIX}/bin/cmake.exe --build .
+}
+
+package() {
+  cd "${srcdir}/build-${MSYSTEM}"
+
+  DESTDIR="${pkgdir}" ${MINGW_PREFIX}/bin/cmake.exe --install .
+
+  install -Dm644 "${srcdir}/${_realname/-/_}-${pkgver}/README.md" "${pkgdir}${MINGW_PREFIX}/share/doc/${_realname}/README.md"
+  install -Dm644 "${srcdir}/${_realname/-/_}-${pkgver}/LICENSE" "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/LICENSE"
+}
+
+# vim:set ts=2 sw=2 et: