From b5093ec17c028b6ffa98fc63ac5ad4eb7db71b89 Mon Sep 17 00:00:00 2001
From: Alexey Pavlov <alexpux@gmail.com>
Date: Mon, 19 Jun 2017 12:28:49 +0300
Subject: [PATCH] python-certifi: New package

---
 mingw-w64-python-certifi/PKGBUILD | 62 +++++++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)
 create mode 100644 mingw-w64-python-certifi/PKGBUILD

diff --git a/mingw-w64-python-certifi/PKGBUILD b/mingw-w64-python-certifi/PKGBUILD
new file mode 100644
index 0000000000..ec41025cbd
--- /dev/null
+++ b/mingw-w64-python-certifi/PKGBUILD
@@ -0,0 +1,62 @@
+# Maintainer: Alexey Pavlov <alexpux@gmail.com>
+
+_realname=certifi
+pkgbase=mingw-w64-python-${_realname}
+pkgname=("${MINGW_PACKAGE_PREFIX}-python2-${_realname}" "${MINGW_PACKAGE_PREFIX}-python3-${_realname}")
+pkgver=2017.4.17
+pkgrel=1
+pkgdesc="Python package for providing Mozilla's CA Bundle (mingw-w64)"
+url='http://pypi.python.org/pypi/certifi'
+license=('GPL')
+arch=('any')
+makedepends=("${MINGW_PACKAGE_PREFIX}-python2-setuptools"
+             "${MINGW_PACKAGE_PREFIX}-python3-setuptools"
+             'mercurial')
+_dtoken="53/72/6c6f1e787d9cab2cc733cf042f125abec07209a58308831c9f292504e826"
+source=("https://pypi.io/packages/source/${_realname:0:1}/${_realname}/${_realname}-${pkgver}.tar.gz")
+sha256sums=('f7527ebf7461582ce95f7a9e03dd141ce810d40590834f4ec20cddd54234c10a')
+
+prepare() {
+  cd ${srcdir}
+  cp -r ${_realname}-${pkgver} build-python2
+  cp -r ${_realname}-${pkgver} build-python3
+  
+  cd build-python2
+  sed -i '1s|python$|python2|' certifi/core.py
+}
+
+package_python3-certifi() {
+  depends=("${MINGW_PACKAGE_PREFIX}-python3")
+  cd ${srcdir}/build-python3
+  ${MINGW_PREFIX}/bin/python3 setup.py build
+  MSYS2_ARG_CONV_EXCL="--prefix=;--install-scripts=;--install-platlib=" \
+  ${MINGW_PREFIX}/bin/python3 setup.py install --prefix=${MINGW_PREFIX} --root="${pkgdir}"
+
+  install -D -m644 LICENSE "${pkgdir}${MINGW_PREFIX}"/share/licenses/python3-${_realname}/LICENSE
+}
+
+package_python2-certifi() {
+  depends=("${MINGW_PACKAGE_PREFIX}-python2")
+  cd ${srcdir}/build-python2
+  ${MINGW_PREFIX}/bin/python2 setup.py build
+  MSYS2_ARG_CONV_EXCL="--prefix=;--install-scripts=;--install-platlib=" \
+  ${MINGW_PREFIX}/bin/python2 setup.py install --prefix=${MINGW_PREFIX} --root="${pkgdir}"
+
+  install -D -m644 LICENSE "${pkgdir}${MINGW_PREFIX}"/share/licenses/python2-${_realname}/LICENSE
+}
+
+package_mingw-w64-i686-python2-certifi() {
+  package_python2-certifi
+}
+
+package_mingw-w64-i686-python3-certifi() {
+  package_python3-certifi
+}
+
+package_mingw-w64-x86_64-python2-certifi() {
+  package_python2-certifi
+}
+
+package_mingw-w64-x86_64-python3-certifi() {
+  package_python3-certifi
+}