diff --git a/mingw-w64-baobab/PKGBUILD b/mingw-w64-baobab/PKGBUILD
new file mode 100644
index 0000000000..33e90669f2
--- /dev/null
+++ b/mingw-w64-baobab/PKGBUILD
@@ -0,0 +1,41 @@
+# Maintainer: Gabriel Rauter <rauter.gabriel@gmail.com>
+
+_realname=baobab
+pkgbase=mingw-w64-${_realname}
+pkgname="${MINGW_PACKAGE_PREFIX}-${_realname}"
+pkgver=3.38.0
+pkgrel=1
+arch=('any')
+pkgdesc="A graphical directory tree analyzer (mingw-w64)"
+url="https://wiki.gnome.org/Apps/DiskUsageAnalyzer"
+depends=("${MINGW_PACKAGE_PREFIX}-gsettings-desktop-schemas"
+         "${MINGW_PACKAGE_PREFIX}-gobject-introspection-runtime"
+         "${MINGW_PACKAGE_PREFIX}-librsvg")
+makedepends=("${MINGW_PACKAGE_PREFIX}-gcc"
+             "${MINGW_PACKAGE_PREFIX}-vala"
+             "${MINGW_PACKAGE_PREFIX}-gobject-introspection"
+             "${MINGW_PACKAGE_PREFIX}-yelp-tools"
+             "${MINGW_PACKAGE_PREFIX}-appstream-glib"
+             "${MINGW_PACKAGE_PREFIX}-meson")
+options=('strip' 'staticlibs')
+license=("GPL2")
+source=("https://download.gnome.org/sources/${_realname}/${pkgver%.*}/${_realname}-${pkgver}.tar.xz")
+sha256sums=('048468147860816b97f15d50b3c84e9acf0539c1441cfeb63703d112e8728329')
+
+build() {
+  [[ -d build-${MINGW_CHOST} ]] && rm -rf build-${MINGW_CHOST}
+  mkdir -p build-${MINGW_CHOST} && cd build-${MINGW_CHOST}
+
+  ${MINGW_PREFIX}/bin/meson \
+    --buildtype=plain \
+    "../${_realname}-${pkgver}"
+
+  ninja
+}
+
+package() {
+  cd "${srcdir}/build-${MINGW_CHOST}"
+  DESTDIR="${pkgdir}${MINGW_PREFIX}" ninja install
+
+  install -Dm644 "${srcdir}/${_realname}-${pkgver}/COPYING" "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/COPYING"
+}