From d492a3609b58256950f4c1c72b1843c30834b098 Mon Sep 17 00:00:00 2001
From: Jeroen Ooms <jeroenooms@gmail.com>
Date: Sun, 7 Mar 2021 13:56:54 +0100
Subject: [PATCH 1/3] New package: TileDB

---
 mingw-w64-tiledb/PKGBUILD | 75 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 75 insertions(+)
 create mode 100644 mingw-w64-tiledb/PKGBUILD

diff --git a/mingw-w64-tiledb/PKGBUILD b/mingw-w64-tiledb/PKGBUILD
new file mode 100644
index 0000000000..cfd424da9a
--- /dev/null
+++ b/mingw-w64-tiledb/PKGBUILD
@@ -0,0 +1,75 @@
+_realname=tiledb
+pkgbase=mingw-w64-${_realname}
+pkgname="${MINGW_PACKAGE_PREFIX}-${_realname}"
+pkgver=2.2.4
+pkgrel=1
+pkgdesc="Storage management library for sparse and dense array data (mingw-w64)"
+arch=("any")
+url="https://tiledb.com/"
+license=("MIT")
+depends=("${MINGW_PACKAGE_PREFIX}-aws-sdk-cpp"
+         "${MINGW_PACKAGE_PREFIX}-lz4"
+         "${MINGW_PACKAGE_PREFIX}-bzip2"
+         "${MINGW_PACKAGE_PREFIX}-zlib"
+         "${MINGW_PACKAGE_PREFIX}-zstd")
+makedepends=("${MINGW_PACKAGE_PREFIX}-cmake"
+             "${MINGW_PACKAGE_PREFIX}-gcc"
+             "${MINGW_PACKAGE_PREFIX}-curl")
+options=("staticlibs" "strip")
+
+source=(${_realname}-${pkgver}.tar.gz::"https://github.com/TileDB-Inc/TileDB/archive/${pkgver}.tar.gz")
+sha256sums=("a9d1050dc51dcdf9bf1f59961bc957552bc39f51eb01000bf40487dd076c00e2")
+noextract=(${_realname}-${pkgver}.tar.gz)
+
+prepare() {
+  # Workaround for symlinks in tarball
+  MSYS="winsymlinks:lnk" tar -xf ${srcdir}/${_realname}-${pkgver}.tar.gz
+  cd "${srcdir}/${_realname}-${pkgver}"
+}
+
+build() {
+  echo "Building static library"
+  [[ -d "${srcdir}/build-${CARCH}-static" ]] && rm -rf "${srcdir}/build-${CARCH}-static"
+  mkdir -p "${srcdir}/build-${CARCH}-static" && cd "${srcdir}/build-${CARCH}-static"
+
+  MSYS2_ARG_CONV_EXCL="-DCMAKE_INSTALL_PREFIX=" \
+  ${MINGW_PREFIX}/bin/cmake.exe \
+    -G"MSYS Makefiles" \
+    -DCMAKE_INSTALL_PREFIX=${MINGW_PREFIX} \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DTILEDB_STATIC=ON \
+    -DTILEDB_S3=ON \
+    -DBUILD_SHARED_LIBS=OFF \
+    ../${_realname}-${pkgver}
+
+  make
+  make -C tiledb
+
+  echo "Building shared library"
+  [[ -d "${srcdir}/build-${CARCH}-shared" ]] && rm -rf "${srcdir}/build-${CARCH}-shared"
+  mkdir -p "${srcdir}/build-${CARCH}-shared" && cd "${srcdir}/build-${CARCH}-shared"
+
+  MSYS2_ARG_CONV_EXCL="-DCMAKE_INSTALL_PREFIX=" \
+  ${MINGW_PREFIX}/bin/cmake.exe \
+    -G"MSYS Makefiles" \
+    -DCMAKE_INSTALL_PREFIX=${MINGW_PREFIX} \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DTILEDB_STATIC=ON \
+    -DTILEDB_S3=ON \
+    -DBUILD_SHARED_LIBS=ON \
+    ../${_realname}-${pkgver}
+
+  make
+  make -C tiledb
+}
+
+package() {
+  cd "${srcdir}/build-${CARCH}-static"
+  make  DESTDIR="${pkgdir}" -C tiledb install
+
+  cd "${srcdir}/build-${CARCH}-shared"
+  make  DESTDIR="${pkgdir}" -C tiledb install
+
+  cd "${srcdir}/${_realname}-${pkgver}"
+  install -Dm644 LICENSE "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/LICENSE"
+}

From e80d060f568bde024f9bcc0431995aa09811fde9 Mon Sep 17 00:00:00 2001
From: Jeroen Ooms <jeroenooms@gmail.com>
Date: Sun, 7 Mar 2021 14:36:52 +0100
Subject: [PATCH 2/3] Explicitly enable SSE2 on i686

---
 mingw-w64-tiledb/PKGBUILD | 6 ++++++
 1 file changed, 6 insertions(+)

diff --git a/mingw-w64-tiledb/PKGBUILD b/mingw-w64-tiledb/PKGBUILD
index cfd424da9a..099be5501b 100644
--- a/mingw-w64-tiledb/PKGBUILD
+++ b/mingw-w64-tiledb/PKGBUILD
@@ -28,6 +28,12 @@ prepare() {
 }
 
 build() {
+  # Enable SSE2 (required) on i686 (these are enabled by default on x64)
+  if [ "$CARCH" == "i686" ]; then
+  export CFLAGS="-mfpmath=sse -msse2"
+  export CXXFLAGS="-mfpmath=sse -msse2"
+  fi
+
   echo "Building static library"
   [[ -d "${srcdir}/build-${CARCH}-static" ]] && rm -rf "${srcdir}/build-${CARCH}-static"
   mkdir -p "${srcdir}/build-${CARCH}-static" && cd "${srcdir}/build-${CARCH}-static"

From 34943f362105ccf175cfab560c7ffa91640590a2 Mon Sep 17 00:00:00 2001
From: Jeroen Ooms <jeroenooms@gmail.com>
Date: Sun, 7 Mar 2021 16:25:47 +0100
Subject: [PATCH 3/3] Fix install dir

---
 mingw-w64-tiledb/PKGBUILD | 4 ++--
 1 file changed, 2 insertions(+), 2 deletions(-)

diff --git a/mingw-w64-tiledb/PKGBUILD b/mingw-w64-tiledb/PKGBUILD
index 099be5501b..2d3c18ec55 100644
--- a/mingw-w64-tiledb/PKGBUILD
+++ b/mingw-w64-tiledb/PKGBUILD
@@ -38,7 +38,7 @@ build() {
   [[ -d "${srcdir}/build-${CARCH}-static" ]] && rm -rf "${srcdir}/build-${CARCH}-static"
   mkdir -p "${srcdir}/build-${CARCH}-static" && cd "${srcdir}/build-${CARCH}-static"
 
-  MSYS2_ARG_CONV_EXCL="-DCMAKE_INSTALL_PREFIX=" \
+  export MSYS2_ARG_CONV_EXCL="-DCMAKE_INSTALL_PREFIX="
   ${MINGW_PREFIX}/bin/cmake.exe \
     -G"MSYS Makefiles" \
     -DCMAKE_INSTALL_PREFIX=${MINGW_PREFIX} \
@@ -55,7 +55,7 @@ build() {
   [[ -d "${srcdir}/build-${CARCH}-shared" ]] && rm -rf "${srcdir}/build-${CARCH}-shared"
   mkdir -p "${srcdir}/build-${CARCH}-shared" && cd "${srcdir}/build-${CARCH}-shared"
 
-  MSYS2_ARG_CONV_EXCL="-DCMAKE_INSTALL_PREFIX=" \
+  export MSYS2_ARG_CONV_EXCL="-DCMAKE_INSTALL_PREFIX="
   ${MINGW_PREFIX}/bin/cmake.exe \
     -G"MSYS Makefiles" \
     -DCMAKE_INSTALL_PREFIX=${MINGW_PREFIX} \