diff --git a/mingw-w64-python-oauthlib/PKGBUILD b/mingw-w64-python-oauthlib/PKGBUILD
new file mode 100644
index 0000000000..6b5dc126c5
--- /dev/null
+++ b/mingw-w64-python-oauthlib/PKGBUILD
@@ -0,0 +1,38 @@
+# Maintainer: Sarah Ottinger <schalaalexiazeal@gmail.com>
+
+_realname=oauthlib
+pkgbase=mingw-w64-python-${_realname}
+pkgname=("${MINGW_PACKAGE_PREFIX}-python-${_realname}")
+pkgver=3.1.0
+pkgrel=1
+pkgdesc='A generic, spec-compliant, thorough implementation of the OAuth request-signing logic (mingw-w64)'
+arch=('any')
+mingw_arch=('mingw32' 'mingw64' 'ucrt64')
+url="https://github.com/idan/oauthlib"
+license=('BSD')
+depends=("${MINGW_PACKAGE_PREFIX}-python-cryptography")
+makedepends=("${MINGW_PACKAGE_PREFIX}-python-setuptools")
+options=('!emptydirs')
+source=("https://files.pythonhosted.org/packages/source/${_realname:0:1}/$_realname/$_realname-$pkgver.tar.gz")
+sha256sums=('bee41cc35fcca6e988463cacc3bcb8a96224f470ca547e697b604cc697b2f889')
+
+prepare() {  
+  cd "$srcdir"
+  rm -rf python-build-${CARCH} | true
+  cp -r "${_realname}-${pkgver}" "python-build-${CARCH}"
+}
+
+build() {
+  msg "Python build for ${CARCH}"  
+  cd "${srcdir}/python-build-${CARCH}"
+  ${MINGW_PREFIX}/bin/python setup.py build
+}
+
+package() {
+  cd "${srcdir}/python-build-${CARCH}"
+  MSYS2_ARG_CONV_EXCL="--prefix=;--install-scripts=;--install-platlib=" \
+  ${MINGW_PREFIX}/bin/python setup.py install --prefix=${MINGW_PREFIX} \
+    --root="${pkgdir}" --optimize=1 --skip-build
+
+  install -D -m644 LICENSE "${pkgdir}${MINGW_PREFIX}/share/licenses/python-${_realname}/LICENSE"
+}