From 44f2646d82c47b417f940e5b7478b08036459e29 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Wolfgang=20St=C3=B6ggl?= <c72578@yahoo.de>
Date: Sun, 30 Aug 2020 09:22:58 +0200
Subject: [PATCH] Add sox package

SoX, the Swiss Army knife of sound processing programs.
http://sox.sourceforge.net/

The last official release of SoX is version 14.4.2 from 2015.
In the meantime, several bugs and CVE have been fixed.
Therefore use a git commit of current master for the package here:
https://sourceforge.net/p/sox/code/ci/784021f/
---
 mingw-w64-sox/PKGBUILD | 76 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 76 insertions(+)
 create mode 100644 mingw-w64-sox/PKGBUILD

diff --git a/mingw-w64-sox/PKGBUILD b/mingw-w64-sox/PKGBUILD
new file mode 100644
index 0000000000..5aa286daef
--- /dev/null
+++ b/mingw-w64-sox/PKGBUILD
@@ -0,0 +1,76 @@
+# Maintainer: Wolfgang Stöggl <c72578@yahoo.de>
+
+_realname=sox
+_base_ver=14.4.2
+pkgbase=mingw-w64-${_realname}
+pkgname="${MINGW_PACKAGE_PREFIX}-${_realname}"
+# https://sourceforge.net/p/sox/code/ci/784021f41f97a65471d961d39474c85ba00318de/
+pkgver=14.4.2.r3197.784021f4
+pkgrel=1
+pkgdesc="SoX is the Swiss Army Knife of sound processing utilities (mingw-w64)"
+arch=('any')
+url="https://sourceforge.net/projects/sox/"
+license=("GPL")
+makedepends=(autoconf-archive git
+             ${MINGW_PACKAGE_PREFIX}-flac
+             ${MINGW_PACKAGE_PREFIX}-gcc
+             ${MINGW_PACKAGE_PREFIX}-gsm
+             ${MINGW_PACKAGE_PREFIX}-id3lib
+             ${MINGW_PACKAGE_PREFIX}-lame
+             ${MINGW_PACKAGE_PREFIX}-libao
+             ${MINGW_PACKAGE_PREFIX}-libid3tag
+             ${MINGW_PACKAGE_PREFIX}-libmad
+             ${MINGW_PACKAGE_PREFIX}-libpng
+             ${MINGW_PACKAGE_PREFIX}-libsndfile
+             ${MINGW_PACKAGE_PREFIX}-libtool
+             ${MINGW_PACKAGE_PREFIX}-libvorbis
+             ${MINGW_PACKAGE_PREFIX}-opencore-amr
+             ${MINGW_PACKAGE_PREFIX}-opusfile
+             ${MINGW_PACKAGE_PREFIX}-pkg-config
+             ${MINGW_PACKAGE_PREFIX}-twolame
+             ${MINGW_PACKAGE_PREFIX}-wavpack)
+depends=(${MINGW_PACKAGE_PREFIX}-gcc-libs
+             ${MINGW_PACKAGE_PREFIX}-flac
+             ${MINGW_PACKAGE_PREFIX}-gsm
+             ${MINGW_PACKAGE_PREFIX}-id3lib
+             ${MINGW_PACKAGE_PREFIX}-lame
+             ${MINGW_PACKAGE_PREFIX}-libao
+             ${MINGW_PACKAGE_PREFIX}-libid3tag
+             ${MINGW_PACKAGE_PREFIX}-libmad
+             ${MINGW_PACKAGE_PREFIX}-libpng
+             ${MINGW_PACKAGE_PREFIX}-libsndfile
+             ${MINGW_PACKAGE_PREFIX}-libvorbis
+             ${MINGW_PACKAGE_PREFIX}-opencore-amr
+             ${MINGW_PACKAGE_PREFIX}-opusfile
+             ${MINGW_PACKAGE_PREFIX}-twolame
+             ${MINGW_PACKAGE_PREFIX}-wavpack)
+options=('staticlibs' 'strip')
+source=("${_realname}"::"git+https://git.code.sf.net/p/sox/code#commit=784021f41f97a65471d961d39474c85ba00318de")
+sha256sums=('SKIP')
+
+prepare() {
+  cd "${srcdir}/${_realname}"
+  autoreconf -i
+}
+
+pkgver() {
+  cd "${srcdir}/${_realname}"
+  printf "%s.r%s.%s" "${_base_ver}" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)" 
+}
+
+build() {
+  mkdir -p "$srcdir/build-${MINGW_CHOST}" && cd "$srcdir/build-${MINGW_CHOST}"
+  ../${_realname}/configure \
+    --prefix=${MINGW_PREFIX} \
+    --build=${MINGW_CHOST} \
+    --host=${MINGW_CHOST} \
+    --with-distro='MSYS2 MINGW-packages'
+
+  make
+}
+
+package() {
+  cd "${srcdir}/build-${MINGW_CHOST}"
+  make DESTDIR="${pkgdir}" install
+  make DESTDIR="${pkgdir}" installcheck
+}