From dfc68eb4b89263e0f441fbebbafc2126ab00ccf1 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?=D9=85=D9=87=D8=AF=D9=8A=20=D8=B4=D9=8A=D9=86=D9=88=D9=86?=
 =?UTF-8?q?=20=28Mehdi=20Chinoune=29?= <mehdi.chinoune@hotmail.com>
Date: Sun, 25 Dec 2022 16:31:19 +0100
Subject: [PATCH] [new-package] python-svgelements 1.9.0

---
 mingw-w64-python-svgelements/PKGBUILD | 42 +++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)
 create mode 100644 mingw-w64-python-svgelements/PKGBUILD

diff --git a/mingw-w64-python-svgelements/PKGBUILD b/mingw-w64-python-svgelements/PKGBUILD
new file mode 100644
index 0000000000..07e12d39d8
--- /dev/null
+++ b/mingw-w64-python-svgelements/PKGBUILD
@@ -0,0 +1,42 @@
+# Contributor: Mehdi Chinoune <mehdi.chinoune@hotmail.com>
+
+_realname=svgelements
+pkgbase=mingw-w64-python-${_realname}
+pkgname=("${MINGW_PACKAGE_PREFIX}-python-${_realname}")
+pkgver=1.9.0
+pkgrel=1
+pkgdesc="Svg Elements Parsing (mingw-w64)"
+arch=('any')
+mingw_arch=('mingw32' 'mingw64' 'ucrt64' 'clang64' 'clang32')
+url='https://github.com/meerk40t/svgelements'
+license=('MIT')
+depends=("${MINGW_PACKAGE_PREFIX}-python")
+makedepends=("${MINGW_PACKAGE_PREFIX}-python-build"
+             "${MINGW_PACKAGE_PREFIX}-python-installer"
+             "${MINGW_PACKAGE_PREFIX}-python-setuptools"
+             "${MINGW_PACKAGE_PREFIX}-python-wheel")
+checkdepends=("${MINGW_PACKAGE_PREFIX}-python-pytest")
+source=("https://pypi.org/packages/source/${_realname::1}/${_realname}/${_realname}-${pkgver}.tar.gz")
+sha256sums=('21ce32f188d7968da07f585d88141c0cd8638049a68813d69c7eb941fa09fad6')
+
+build() {
+  cp -r "${_realname}-${pkgver}" "python-build-${MSYSTEM}" && cd "python-build-${MSYSTEM}"
+
+  ${MINGW_PREFIX}/bin/python -m build --wheel --skip-dependency-check --no-isolation
+}
+
+check() {
+  cd "${srcdir}/python-build-${MSYSTEM}"
+
+  ${MINGW_PREFIX}/bin/python -m pytest
+}
+
+package() {
+  cd "${srcdir}/python-build-${MSYSTEM}"
+
+  MSYS2_ARG_CONV_EXCL="--prefix=" \
+    ${MINGW_PREFIX}/bin/python -m installer --prefix=${MINGW_PREFIX} \
+    --destdir="${pkgdir}" dist/*.whl
+
+  install -Dm644 LICENSE "${pkgdir}${MINGW_PREFIX}/share/licenses/python-${_realname}/LICENSE"
+}