diff --git a/mingw-w64-python-markdown-it-py/PKGBUILD b/mingw-w64-python-markdown-it-py/PKGBUILD
new file mode 100644
index 0000000000..68d96dcbd3
--- /dev/null
+++ b/mingw-w64-python-markdown-it-py/PKGBUILD
@@ -0,0 +1,41 @@
+# Maintainer: Konstantin Podsvirov <konstantin@podsvirov.pro>
+
+_realname=markdown-it-py
+pkgbase=mingw-w64-python-${_realname}
+pkgname=("${MINGW_PACKAGE_PREFIX}-python-${_realname}")
+pkgver=1.1.0
+pkgrel=1
+pkgdesc='Python port of markdown-it. Markdown parsing, done right! (mingw-w64)'
+arch=('any')
+mingw_arch=('mingw32' 'mingw64' 'ucrt64' 'clang64' 'clang32')
+url='https://github.com/executablebooks/markdown-it-py'
+license=('MIT')
+depends=("${MINGW_PACKAGE_PREFIX}-python-attrs")
+makedepends=("${MINGW_PACKAGE_PREFIX}-python-setuptools")
+source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
+sha256sums=('24d63b5009c224a1df816556f810c4a4042b7f31b77620d855f8b2e7adcbd915')
+
+build() {
+  cd "${srcdir}"
+  cp -r "${_realname}-${pkgver}" "python-build-${MSYSTEM}" && cd "python-build-${MSYSTEM}"
+
+  "${MINGW_PREFIX}"/bin/python setup.py build
+}
+
+package() {
+  cd "${srcdir}/python-build-${MSYSTEM}"
+
+  MSYS2_ARG_CONV_EXCL="--prefix=;--install-scripts=;--install-platlib=" \
+    "${MINGW_PREFIX}"/bin/python setup.py install --prefix="${MINGW_PREFIX}" \
+      --root="${pkgdir}" --optimize=1 --skip-build
+
+  install -Dm644 LICENSE "${pkgdir}${MINGW_PREFIX}/share/licenses/python-${_realname}/LICENSE"
+  install -Dm644 README.md "${pkgdir}${MINGW_PREFIX}/share/doc/python-${_realname}/README.md"
+
+  for _f in "${pkgdir}${MINGW_PREFIX}"/bin/*-script.py; do
+    # Remove shebang line
+    sed -e '1 { s/^#!.*$// }' -i "${_f}"
+  done
+}
+
+# vim:set ts=2 sw=2 et: