From e7e26b8e471b3e129bb175d49eaa2eef3f40b2c7 Mon Sep 17 00:00:00 2001
From: Francis Giraldeau <francis.giraldeau@gmail.com>
Date: Sat, 3 Nov 2018 01:00:37 -0400
Subject: [PATCH] Add cvode package (#4608)

CVODE is a solver for systems of ordinary differential equations.

Signed-off-by: Francis Giraldeau <francis.giraldeau@nrc-cnrc.gc.ca>
---
 mingw-w64-cvode/PKGBUILD | 44 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)
 create mode 100644 mingw-w64-cvode/PKGBUILD

diff --git a/mingw-w64-cvode/PKGBUILD b/mingw-w64-cvode/PKGBUILD
new file mode 100644
index 0000000000..293a3436c4
--- /dev/null
+++ b/mingw-w64-cvode/PKGBUILD
@@ -0,0 +1,44 @@
+# Maintainer: Francis Giraldeau <francis.giraldeau@nrc-cnrc.gc.ca>
+
+_realname=cvode
+pkgbase=mingw-w64-${_realname}
+pkgname="${MINGW_PACKAGE_PREFIX}-${_realname}"
+pkgver=3.2.1
+pkgrel=1
+pkgdesc="ordinary differential equation system solver (mingw-w64)"
+arch=('any')
+url="https://computation.llnl.gov/projects/sundials"
+license=('BSD')
+makedepends=("${MINGW_PACKAGE_PREFIX}-cmake")
+source=("${_realname}-${pkgver}.tar.gz"::https://computation.llnl.gov/projects/sundials/download/${_realname}-${pkgver}.tar.gz)
+sha256sums=('aa4f5f3c5114e93ba246630cf107b1f73de5c1028a013602c114d3cde6564451')
+
+build() {
+  [[ -d build-${MINGW_CHOST} ]] && rm -rf build-${MINGW_CHOST}
+  mkdir -p build-${MINGW_CHOST}
+  cd build-${MINGW_CHOST}
+
+  MSYS2_ARG_CONV_EXCL="-DCMAKE_INSTALL_PREFIX=" \
+  ${MINGW_PREFIX}/bin/cmake.exe \
+    -G"MSYS Makefiles" \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DCMAKE_INSTALL_PREFIX=${MINGW_PREFIX} \
+    ../${_realname}-${pkgver}
+
+  make
+}
+
+package() {
+  cd build-${MINGW_CHOST}
+  make DESTDIR=${pkgdir} install
+
+  # The DLLs must be in the bin runtime directory to be found
+  mkdir -p ${pkgdir}${MINGW_PREFIX}/bin
+  mv ${pkgdir}${MINGW_PREFIX}/lib/*.dll ${pkgdir}${MINGW_PREFIX}/bin/
+
+  # license
+  rm ${pkgdir}${MINGW_PREFIX}/include/sundials/LICENSE
+  install -D -m644 ${srcdir}/${_realname}-${pkgver}/LICENSE \
+  ${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/LICENSE
+}
+