diff --git a/mingw-w64-python-arrow/PKGBUILD b/mingw-w64-python-arrow/PKGBUILD
new file mode 100644
index 0000000000..9f0a38c365
--- /dev/null
+++ b/mingw-w64-python-arrow/PKGBUILD
@@ -0,0 +1,42 @@
+# Maintainer: @naveen521kk on Github, Naveen M K <naveen@syrusdark.website>
+
+_pyname=arrow
+_realname=arrow
+pkgbase=mingw-w64-python-${_realname}
+pkgname=("${MINGW_PACKAGE_PREFIX}-python-${_realname}")
+pkgver=1.0.3
+pkgrel=1
+pkgdesc='Better dates & times for Python (mingw-w64)'
+arch=('any')
+url="https://arrow.readthedocs.io/"
+license=('Apache-2.0')
+depends=(
+  "${MINGW_PACKAGE_PREFIX}-python"
+  "${MINGW_PACKAGE_PREFIX}-python-dateutil"
+)
+makedepends=(
+  "${MINGW_PACKAGE_PREFIX}-python-setuptools"
+)
+source=("${_pyname}-${pkgver}.tar.gz::https://pypi.org/packages/source/${_pyname::1}/${_pyname}/${_pyname}-${pkgver}.tar.gz")
+sha256sums=('399c9c8ae732270e1aa58ead835a79a40d7be8aa109c579898eb41029b5a231d')
+
+prepare() {  
+  cd "$srcdir"
+  rm -rf python-build-${CARCH} | true
+  cp -r "${_pyname//_/-}-$pkgver" "python-build-${CARCH}"
+  export SETUPTOOLS_SCM_PRETEND_VERSION=${pkgver}
+}
+
+build() {
+  msg "Python build for ${CARCH}"  
+  cd "${srcdir}/python-build-${CARCH}"
+  ${MINGW_PREFIX}/bin/python setup.py build
+}
+
+package() {
+  cd "${srcdir}/python-build-${CARCH}"
+  MSYS2_ARG_CONV_EXCL="--prefix=;--install-scripts=;--install-platlib=" \
+  ${MINGW_PREFIX}/bin/python setup.py install --prefix=${MINGW_PREFIX} \
+    --root="${pkgdir}" --optimize=1 --skip-build
+  install -Dm644 LICENSE "${pkgdir}${MINGW_PREFIX}/share/licenses/python-${_realname}/LICENSE"
+}