50 lines
1.4 KiB
Bash
50 lines
1.4 KiB
Bash
# Maintainer: Marty Plummer (The_NetZ) <ntzrmtthihu777 (at) gmail (dot) com>
|
|
|
|
_realname=SDL_gfx
|
|
pkgbase=mingw-w64-${_realname}
|
|
pkgname=${MINGW_PACKAGE_PREFIX}-${_realname}
|
|
pkgver=2.0.27
|
|
pkgrel=1
|
|
pkgdesc="SDL Graphic Primitives (mingw-w64)"
|
|
arch=('any')
|
|
mingw_arch=('mingw32' 'mingw64' 'ucrt64' 'clang64' 'clangarm64')
|
|
url="https://www.ferzkopp.net/joomla/software-mainmenu-14/4-ferzkopps-linux-software/19-sdlgfx"
|
|
license=('LGPL')
|
|
depends=("${MINGW_PACKAGE_PREFIX}-SDL")
|
|
makedepends=("${MINGW_PACKAGE_PREFIX}-cc" "${MINGW_PACKAGE_PREFIX}-autotools")
|
|
source=("https://www.ferzkopp.net/Software/SDL_gfx-2.0/${_realname}-${pkgver}.tar.gz")
|
|
sha256sums=('dfb15ac5f8ce7a4952dc12d2aed9747518c5e6b335c0e31636d23f93c630f419')
|
|
|
|
prepare() {
|
|
cd ${_realname}-${pkgver}
|
|
autoreconf -fiv
|
|
}
|
|
|
|
build() {
|
|
mkdir -p "${srcdir}/build-${MSYSTEM}" && cd "${srcdir}/build-${MSYSTEM}"
|
|
|
|
declare -a _extra_config
|
|
|
|
if [[ $CARCH == "aarch64" ]]; then
|
|
_extra_config+=("--disable-mmx")
|
|
fi
|
|
|
|
../${_realname}-${pkgver}/configure \
|
|
--prefix=${MINGW_PREFIX} \
|
|
--build=${MINGW_CHOST} \
|
|
--host=${MINGW_CHOST} \
|
|
"${_extra_config[@]}" \
|
|
--enable-shared \
|
|
--enable-static
|
|
|
|
make
|
|
}
|
|
|
|
package() {
|
|
cd "${srcdir}/build-${MSYSTEM}"
|
|
|
|
make DESTDIR="${pkgdir}" install
|
|
install -Dm644 "${srcdir}/${_realname}-${pkgver}/COPYING" \
|
|
"${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/LICENSE"
|
|
}
|