62308009e7
Except the provides in libc++ for backwards compat. No rebuilds now, as that's not worth the resources.
70 lines
2.0 KiB
Bash
70 lines
2.0 KiB
Bash
# Contributor: Mehdi Chinoune <mehdi.chinoune@hotmail.com>
|
|
|
|
_realname=coin-or-clp
|
|
pkgbase=mingw-w64-${_realname}
|
|
pkgname=("${MINGW_PACKAGE_PREFIX}-${_realname}")
|
|
pkgver=1.17.10
|
|
pkgrel=1
|
|
pkgdesc="COIN-OR Linear Programming Solver. (mingw-w64)"
|
|
arch=('any')
|
|
mingw_arch=('ucrt64' 'clang64' 'clangarm64')
|
|
url='https://github.com/coin-or/Clp'
|
|
msys2_references=(
|
|
'archlinux: coin-or-clp'
|
|
)
|
|
license=('spdx:EPL-2.0')
|
|
groups=("${MINGW_PACKAGE_PREFIX}-coin-or")
|
|
depends=("${MINGW_PACKAGE_PREFIX}-cc-libs"
|
|
"${MINGW_PACKAGE_PREFIX}-coin-or-asl"
|
|
"${MINGW_PACKAGE_PREFIX}-coin-or-coinutils"
|
|
"${MINGW_PACKAGE_PREFIX}-coin-or-osi"
|
|
"${MINGW_PACKAGE_PREFIX}-suitesparse")
|
|
makedepends=("${MINGW_PACKAGE_PREFIX}-cc"
|
|
"${MINGW_PACKAGE_PREFIX}-autotools"
|
|
"${MINGW_PACKAGE_PREFIX}-coin-or-buildtools")
|
|
source=("${url}/archive/releases/${pkgver}/${_realname}-${pkgver}.tar.gz")
|
|
sha256sums=('0d79ece896cdaa4a3855c37f1c28e6c26285f74d45f635046ca0b6d68a509885')
|
|
|
|
prepare() {
|
|
cp -r ${MINGW_PREFIX}/share/coin-or-buildtools/BuildTools Clp-releases-${pkgver}/Clp
|
|
|
|
cd Clp-releases-${pkgver}/Clp
|
|
|
|
ACLOCAL="aclocal -I${srcdir}/Clp-releases-${pkgver}/Clp/BuildTools" \
|
|
autoreconf -fiv
|
|
}
|
|
|
|
build() {
|
|
mkdir -p "${srcdir}/build-${MSYSTEM}" && cd "${srcdir}/build-${MSYSTEM}"
|
|
|
|
export lt_cv_deplibs_check_method='pass_all'
|
|
|
|
CFLAGS+=" -Wno-implicit-function-declaration" \
|
|
../"Clp-releases-${pkgver}"/Clp/configure \
|
|
--prefix="${MINGW_PREFIX}" \
|
|
--enable-shared \
|
|
--disable-static \
|
|
--enable-dependency-linking \
|
|
--with-cholmod-lib='-lcholmod' \
|
|
--with-cholmod-incdir=${MINGW_PREFIX}/include/suitesparse \
|
|
--with-amd-lib='-lamd' \
|
|
--with-amd-incdir=${MINGW_PREFIX}/include/suitesparse \
|
|
ac_cv_c_compiler_gnu=yes
|
|
|
|
make
|
|
}
|
|
|
|
check() {
|
|
cd "${srcdir}/build-${MSYSTEM}"
|
|
|
|
make check
|
|
}
|
|
|
|
package() {
|
|
cd "${srcdir}/build-${MSYSTEM}"
|
|
|
|
make install DESTDIR="${pkgdir}"
|
|
|
|
install -Dm644 "${srcdir}/Clp-releases-${pkgver}/LICENSE" "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/LICENSE"
|
|
}
|