62308009e7
Except the provides in libc++ for backwards compat. No rebuilds now, as that's not worth the resources.
43 lines
1.4 KiB
Bash
43 lines
1.4 KiB
Bash
# Maintainers: James Spencer <james.s.spencer@gmail.com>
|
|
# Darjan Krijan [https://disc-kuraudo.eu]
|
|
|
|
_realname=cubew
|
|
pkgbase=mingw-w64-${_realname}
|
|
pkgname=("${MINGW_PACKAGE_PREFIX}-${_realname}")
|
|
pkgver=4.8.2
|
|
pkgrel=1
|
|
pkgdesc="High-performance library for writing a multi-dimensional performance space (mingw-w64)"
|
|
arch=('any')
|
|
mingw_arch=('mingw64' 'ucrt64' 'clang64' 'clangarm64')
|
|
url="http://www.scalasca.org/software/cube-4.x/download.html"
|
|
license=('BSD')
|
|
depends=("${MINGW_PACKAGE_PREFIX}-cc-libs"
|
|
"${MINGW_PACKAGE_PREFIX}-zlib")
|
|
makedepends=("${MINGW_PACKAGE_PREFIX}-cc"
|
|
"${MINGW_PACKAGE_PREFIX}-fc")
|
|
source=("https://apps.fz-juelich.de/scalasca/releases/cube/${pkgver:0:3}/dist/${_realname}-${pkgver}.tar.gz")
|
|
sha256sums=('4f3bcf0622c2429b8972b5eb3f14d79ec89b8161e3c1cc5862ceda417d7975d2')
|
|
|
|
build() {
|
|
mkdir -p "${srcdir}/build-${MSYSTEM}" && cd "${srcdir}/build-${MSYSTEM}"
|
|
|
|
local -a extra_args
|
|
if [[ ${MINGW_PACKAGE_PREFIX} == *-clang-* ]]; then
|
|
extra_args+="--with-nocross-compiler-suite=clang"
|
|
fi
|
|
|
|
../${_realname}-${pkgver}/configure \
|
|
--prefix=${MINGW_PREFIX} \
|
|
--with-gnu-ld \
|
|
--enable-shared \
|
|
"${extra_args[@]}" \
|
|
|
|
make
|
|
}
|
|
|
|
package() {
|
|
cd "${srcdir}/build-${MSYSTEM}"
|
|
make install DESTDIR="${pkgdir}"
|
|
install -Dm644 "${srcdir}"/${_realname}-${pkgver}/COPYING "${pkgdir}"${MINGW_PREFIX}/share/licenses/${_realname}/LICENSE
|
|
}
|