715895ab3b
* gstreamer: Update to 1.26.7 * gst-plugins-base: Update to 1.26.7 * gst-plugins-good: Update to 1.26.7 * gst-plugins-bad: Update to 1.26.7 * gst-plugins-ugly: Update to 1.26.7 * gst-libav: Update to 1.26.7 * gst-editing-services: Update to 1.26.7 * gst-rtsp-server: Update to 1.26.7 * gst-python: Update to 1.26.7 * gst-devtools: Update to 1.26.7 * gst-plugins-rs: Update to 1.26.7
55 lines
2.0 KiB
Bash
55 lines
2.0 KiB
Bash
# Maintainer: Lubosz Sarnecki <lubosz@gmail.com>
|
|
|
|
_realname=gst-python
|
|
pkgbase=mingw-w64-${_realname}
|
|
pkgname=("${MINGW_PACKAGE_PREFIX}-gst-python")
|
|
pkgver=1.26.7
|
|
pkgrel=1
|
|
pkgdesc="GStreamer GObject Introspection overrides for Python (mingw-w64)"
|
|
arch=('any')
|
|
mingw_arch=('mingw64' 'ucrt64' 'clang64' 'clangarm64')
|
|
license=('spdx:LGPL-2.1-or-later')
|
|
depends=("${MINGW_PACKAGE_PREFIX}-glib2"
|
|
"${MINGW_PACKAGE_PREFIX}-gstreamer"
|
|
"${MINGW_PACKAGE_PREFIX}-gst-plugins-base"
|
|
"${MINGW_PACKAGE_PREFIX}-gst-plugins-bad-libs"
|
|
"${MINGW_PACKAGE_PREFIX}-python-gobject")
|
|
makedepends=("${MINGW_PACKAGE_PREFIX}-cc"
|
|
"${MINGW_PACKAGE_PREFIX}-meson"
|
|
"${MINGW_PACKAGE_PREFIX}-ninja"
|
|
"${MINGW_PACKAGE_PREFIX}-pkgconf"
|
|
"${MINGW_PACKAGE_PREFIX}-python"
|
|
"${MINGW_PACKAGE_PREFIX}-gst-rtsp-server")
|
|
url='https://gstreamer.freedesktop.org/modules/gst-python.html'
|
|
source=("https://gstreamer.freedesktop.org/src/gst-python/${_realname}-${pkgver}.tar.xz"{,.asc})
|
|
sha256sums=('7a544b7968b181c2965e979f2ce889db36397790de9a7c312cf468b51d26428c'
|
|
'SKIP')
|
|
validpgpkeys=('D637032E45B8C6585B9456565D2EEE6F6F349D7C') # Tim Müller <tim@gstreamer-foundation.org>
|
|
|
|
build() {
|
|
mkdir -p "${srcdir}/build-${MSYSTEM}" && cd "${srcdir}/build-${MSYSTEM}"
|
|
|
|
MSYS2_ARG_CONV_EXCL="--prefix=" \
|
|
${MINGW_PREFIX}/bin/meson.exe setup \
|
|
--prefix="${MINGW_PREFIX}" \
|
|
--buildtype plain \
|
|
--wrap-mode=nofallback \
|
|
-Dauto_features=enabled \
|
|
-Dpython=${MINGW_PREFIX}/bin/python.exe \
|
|
../${_realname}-${pkgver}
|
|
|
|
${MINGW_PREFIX}/bin/meson.exe compile
|
|
}
|
|
|
|
package() {
|
|
cd "${srcdir}/build-${MSYSTEM}"
|
|
|
|
DESTDIR="${pkgdir}" ${MINGW_PREFIX}/bin/meson.exe install
|
|
|
|
# The python plugin loader makes problems because it links against libpython
|
|
# which might be in conflict one already used loading the plugin.
|
|
# The overrides don't need it so just remove it for now.
|
|
# https://github.com/Alexpux/MINGW-packages/issues/2034
|
|
rm -r "${pkgdir}${MINGW_PREFIX}/lib/gstreamer-1.0"
|
|
}
|