78 lines
2.3 KiB
Bash
78 lines
2.3 KiB
Bash
# Maintainer: Alexey Pavlov <alexpux@gmail.com>
|
|
|
|
_realname=libarchive
|
|
pkgbase=mingw-w64-${_realname}
|
|
pkgname="${MINGW_PACKAGE_PREFIX}-${_realname}"
|
|
pkgver=3.8.2
|
|
pkgrel=1
|
|
pkgdesc="Multi-format archive and compression library (mingw-w64)"
|
|
arch=('any')
|
|
mingw_arch=('mingw32' 'mingw64' 'ucrt64' 'clang64' 'clangarm64')
|
|
url="https://www.libarchive.org/"
|
|
msys2_repository_url='https://github.com/libarchive/libarchive/'
|
|
msys2_references=(
|
|
'archlinux: libarchive'
|
|
"cpe: cpe:/a:libarchive:libarchive"
|
|
'cygwin: libarchive'
|
|
'gentoo: app-arch/libarchive'
|
|
)
|
|
license=("spdx:BSD-2-Clause")
|
|
makedepends=("${MINGW_PACKAGE_PREFIX}-cc" "${MINGW_PACKAGE_PREFIX}-autotools")
|
|
depends=(${MINGW_PACKAGE_PREFIX}-cc-libs
|
|
${MINGW_PACKAGE_PREFIX}-bzip2
|
|
${MINGW_PACKAGE_PREFIX}-expat
|
|
${MINGW_PACKAGE_PREFIX}-libb2
|
|
${MINGW_PACKAGE_PREFIX}-libiconv
|
|
${MINGW_PACKAGE_PREFIX}-lz4
|
|
${MINGW_PACKAGE_PREFIX}-libsystre
|
|
${MINGW_PACKAGE_PREFIX}-openssl
|
|
${MINGW_PACKAGE_PREFIX}-xz
|
|
${MINGW_PACKAGE_PREFIX}-zlib
|
|
${MINGW_PACKAGE_PREFIX}-zstd)
|
|
source=("https://github.com/libarchive/libarchive/releases/download/v${pkgver}/${_realname}-${pkgver}.tar.xz")
|
|
sha256sums=('db0dee91561cbd957689036a3a71281efefd131d35d1d98ebbc32720e4da58e2')
|
|
|
|
prepare() {
|
|
cd "${srcdir}/${_realname}-${pkgver}"
|
|
|
|
autoreconf -fiv
|
|
}
|
|
|
|
build() {
|
|
mkdir -p "${srcdir}/build-${MSYSTEM}" && cd "${srcdir}/build-${MSYSTEM}"
|
|
|
|
if [ "${CARCH}" = "i686" ]; then
|
|
# Need for 32-bit toolchain to have 64bit time
|
|
CFLAGS+=" -D__MINGW_USE_VC2005_COMPAT"
|
|
fi
|
|
|
|
# Mention default options explicitly to clarify any confusion
|
|
../${_realname}-${pkgver}/configure \
|
|
--build="${MINGW_CHOST}" \
|
|
--host="${MINGW_CHOST}" \
|
|
--target="${MINGW_CHOST}" \
|
|
--prefix="${MINGW_PREFIX}" \
|
|
--without-xml2 \
|
|
--without-lzo2 \
|
|
--without-nettle \
|
|
--with-openssl \
|
|
--without-libiconv-prefix \
|
|
--with-cng
|
|
|
|
make
|
|
}
|
|
|
|
check() {
|
|
cd "${srcdir}/build-${MSYSTEM}"
|
|
make check
|
|
}
|
|
|
|
package() {
|
|
cd "${srcdir}/build-${MSYSTEM}"
|
|
make DESTDIR="${pkgdir}" install
|
|
|
|
#fix issue with hard-coded path in libarchive.pc file.
|
|
_localpath=$(cygpath -wm ${MINGW_PREFIX})
|
|
sed -i -e "s|${_localpath}|${MINGW_PREFIX}|g" "${pkgdir}"/${MINGW_PREFIX}/lib/pkgconfig/libarchive.pc
|
|
}
|