51 lines
1.2 KiB
Bash
51 lines
1.2 KiB
Bash
# Maintainer: Alexey Pavlov <alexpux@gmail.com>
|
|
|
|
_realname=lzo2
|
|
pkgbase=mingw-w64-${_realname}
|
|
pkgname="${MINGW_PACKAGE_PREFIX}-${_realname}"
|
|
pkgver=2.10
|
|
pkgrel=2
|
|
pkgdesc="Portable lossless data compression library (mingw-w64)"
|
|
arch=(any)
|
|
mingw_arch=('mingw32' 'mingw64' 'ucrt64' 'clang64' 'clangarm64')
|
|
msys2_references=(
|
|
'archlinux: lzo'
|
|
'cpe: cpe:2.3:a:lzo_project:lzo'
|
|
)
|
|
url="https://www.oberhumer.com/opensource/lzo"
|
|
license=("GPL")
|
|
makedepends=("${MINGW_PACKAGE_PREFIX}-cc" "${MINGW_PACKAGE_PREFIX}-autotools")
|
|
source=("$url/download/lzo-${pkgver}.tar.gz")
|
|
sha256sums=('c0f892943208266f9b6543b3ae308fab6284c5c90e627931446fb49b4221a072')
|
|
|
|
prepare() {
|
|
cd "${srcdir}/lzo-${pkgver}"
|
|
# autoreconf to get updated libtool files with clang support
|
|
autoreconf -fiv
|
|
}
|
|
|
|
build() {
|
|
mkdir -p "${srcdir}"/build-${MSYSTEM} && cd "${srcdir}"/build-${MSYSTEM}
|
|
|
|
../lzo-${pkgver}/configure \
|
|
--prefix=${MINGW_PREFIX} \
|
|
--host=${MINGW_CHOST} \
|
|
--build=${MINGW_CHOST} \
|
|
--target=${MINGW_CHOST} \
|
|
--enable-static \
|
|
--enable-shared
|
|
|
|
make
|
|
}
|
|
|
|
check() {
|
|
cd "${srcdir}/build-${MSYSTEM}"
|
|
make check
|
|
make test
|
|
}
|
|
|
|
package() {
|
|
cd "${srcdir}/build-${MSYSTEM}"
|
|
make DESTDIR="${pkgdir}" install
|
|
}
|