67 lines
2.2 KiB
Bash
67 lines
2.2 KiB
Bash
# Contributor: Mehdi Chinoune <mehdi.chinoune@hotmail.com>
|
|
|
|
_realname=openslide
|
|
pkgbase="mingw-w64-${_realname}"
|
|
pkgname=("${MINGW_PACKAGE_PREFIX}-${_realname}")
|
|
pkgver=4.0.0
|
|
pkgrel=4
|
|
pkgdesc='C library for reading virtual slide images (mingw-w64)'
|
|
arch=(any)
|
|
mingw_arch=('mingw64' 'ucrt64' 'clang64' 'clangarm64')
|
|
url='https://openslide.org'
|
|
msys2_repository_url="https://github.com/openslide/openslide"
|
|
license=('spdx:LGPL-2.1-or-later')
|
|
depends=("${MINGW_PACKAGE_PREFIX}-cairo"
|
|
"${MINGW_PACKAGE_PREFIX}-gdk-pixbuf2"
|
|
"${MINGW_PACKAGE_PREFIX}-glib2"
|
|
"${MINGW_PACKAGE_PREFIX}-libdicom"
|
|
"${MINGW_PACKAGE_PREFIX}-libjpeg"
|
|
"${MINGW_PACKAGE_PREFIX}-libpng"
|
|
"${MINGW_PACKAGE_PREFIX}-libtiff"
|
|
"${MINGW_PACKAGE_PREFIX}-libxml2"
|
|
"${MINGW_PACKAGE_PREFIX}-openjpeg2"
|
|
"${MINGW_PACKAGE_PREFIX}-sqlite3"
|
|
"${MINGW_PACKAGE_PREFIX}-zlib")
|
|
makedepends=("${MINGW_PACKAGE_PREFIX}-cc"
|
|
"${MINGW_PACKAGE_PREFIX}-meson")
|
|
source=("https://github.com/openslide/openslide/releases/download/v${pkgver}/${_realname}-${pkgver}.tar.xz"
|
|
"001-undef-OUT.patch")
|
|
sha256sums=('cc227c44316abb65fb28f1c967706eb7254f91dbfab31e9ae6a48db6cf4ae562'
|
|
'd5fbc15f521f5e4a80e1a0f0e1e17084d5df15a6a722e9414c9826fced721d61')
|
|
|
|
prepare() {
|
|
cd "${srcdir}"/${_realname}-${pkgver}
|
|
patch -p1 -i "${srcdir}"/001-undef-OUT.patch
|
|
}
|
|
|
|
build() {
|
|
mkdir -p "${srcdir}/build-${MSYSTEM}" && cd "${srcdir}/build-${MSYSTEM}"
|
|
|
|
declare -a _extra_config
|
|
if check_option "debug" "n"; then
|
|
_extra_config+=("--buildtype=release")
|
|
else
|
|
_extra_config+=("--buildtype=debug")
|
|
fi
|
|
|
|
MSYS2_ARG_CONV_EXCL="--prefix=" \
|
|
${MINGW_PREFIX}/bin/meson setup \
|
|
--prefix="${MINGW_PREFIX}" \
|
|
--wrap-mode=nodownload \
|
|
--auto-features=enabled \
|
|
-Dtest=disabled \
|
|
-Ddoc=disabled \
|
|
"${_extra_config[@]}" \
|
|
../${_realname}-${pkgver}
|
|
|
|
${MINGW_PREFIX}/bin/meson compile
|
|
}
|
|
|
|
package() {
|
|
cd "${srcdir}"/build-${MSYSTEM}
|
|
DESTDIR="${pkgdir}" ${MINGW_PREFIX}/bin/meson install
|
|
|
|
install -Dm644 "${srcdir}"/${_realname}-${pkgver}/COPYING.LESSER \
|
|
"${pkgdir}"${MINGW_PREFIX}/share/licenses/${_realname}/LICENSE
|
|
}
|