63 lines
2.0 KiB
Bash
63 lines
2.0 KiB
Bash
# Maintainer: Alexey Pavlov <alexpux@gmail.com>
|
|
|
|
_realname=osgbullet
|
|
pkgbase=mingw-w64-${_realname}-git
|
|
pkgname=("${MINGW_PACKAGE_PREFIX}-${_realname}-git")
|
|
_ver_base=3.0.0
|
|
pkgver=3.0.0.267
|
|
pkgrel=1
|
|
pkgdesc="Bullet physics and OpenSceneGraph integration (mingw-w64)"
|
|
arch=('any')
|
|
mingw_arch=('mingw64' 'ucrt64' 'clang64' 'clangarm64')
|
|
license=('spdx:LGPL-2.1')
|
|
url="https://github.com/mccdo/osgbullet/"
|
|
provides=("${MINGW_PACKAGE_PREFIX}-${_realname}")
|
|
conflicts=("${MINGW_PACKAGE_PREFIX}-${_realname}")
|
|
depends=("${MINGW_PACKAGE_PREFIX}-bullet"
|
|
"${MINGW_PACKAGE_PREFIX}-OpenSceneGraph"
|
|
"${MINGW_PACKAGE_PREFIX}-osgworks")
|
|
makedepends=("${MINGW_PACKAGE_PREFIX}-cc"
|
|
"${MINGW_PACKAGE_PREFIX}-cmake"
|
|
"${MINGW_PACKAGE_PREFIX}-ninja"
|
|
"git")
|
|
_commit=b89f69617b2017a395c745c76372ac23d4648414
|
|
source=("${_realname}::git+https://github.com/mccdo/osgbullet.git#commit=${_commit}")
|
|
sha256sums=('41ecdcb8ece13856632349d7280bfb7f21e93669e54a52b1c9cc3e2dffa023b2')
|
|
|
|
pkgver() {
|
|
cd "${srcdir}/${_realname}"
|
|
printf "%s.%s" "${_ver_base}" "$(git rev-list --count HEAD)"
|
|
}
|
|
|
|
build() {
|
|
mkdir -p "${srcdir}"/build-${MSYSTEM} && cd "${srcdir}"/build-${MSYSTEM}
|
|
|
|
declare -a _extra_config
|
|
if check_option "debug" "n"; then
|
|
_extra_config+=("-DCMAKE_BUILD_TYPE=Release")
|
|
else
|
|
_extra_config+=("-DCMAKE_BUILD_TYPE=Debug")
|
|
fi
|
|
|
|
MSYS2_ARG_CONV_EXCL="-DCMAKE_INSTALL_PREFIX=" \
|
|
"${MINGW_PREFIX}"/bin/cmake.exe \
|
|
-GNinja \
|
|
-DCMAKE_INSTALL_PREFIX="${MINGW_PREFIX}" \
|
|
-DCMAKE_POLICY_VERSION_MINIMUM=3.5 \
|
|
"${_extra_config[@]}" \
|
|
-DosgWorks_DIR="${MINGW_PREFIX}"/lib \
|
|
../${_realname}
|
|
|
|
"${MINGW_PREFIX}"/bin/cmake.exe --build .
|
|
}
|
|
|
|
package() {
|
|
cd "${srcdir}"/build-${MSYSTEM}
|
|
|
|
DESTDIR="${pkgdir}" "${MINGW_PREFIX}"/bin/cmake.exe --install .
|
|
|
|
# support relocation
|
|
local MINGW_PREFIX_W=$(cygpath -m "${MINGW_PREFIX}")
|
|
sed -i "s#${MINGW_PREFIX_W}#\${_IMPORT_PREFIX}#g" "${pkgdir}${MINGW_PREFIX}"/lib/osgbullet-targets-release.cmake
|
|
}
|