47 lines
1.7 KiB
Bash
47 lines
1.7 KiB
Bash
# Maintainer: J. Peter Mugaas <jpmugaas@suddenlink.net>.
|
|
|
|
_realname=asgiref
|
|
pkgbase=mingw-w64-python-${_realname}
|
|
pkgname=("${MINGW_PACKAGE_PREFIX}-python-${_realname}")
|
|
pkgver=3.10.0
|
|
pkgrel=1
|
|
pkgdesc="Reference ASGI adapters and channel layers (mingw-w64)"
|
|
arch=('any')
|
|
mingw_arch=('mingw64' 'ucrt64' 'clang64' 'clangarm64')
|
|
msys2_references=(
|
|
'archlinux: python-asgiref'
|
|
'gentoo: dev-python/asgiref'
|
|
'purl: pkg:pypi/asgiref'
|
|
)
|
|
msys2_repository_url='https://github.com/django/asgiref'
|
|
url='https://asgi.readthedocs.io/'
|
|
msys2_changelog_url='https://github.com/django/asgiref/blob/main/CHANGELOG.txt'
|
|
license=('spdx:BSD-3-Clause')
|
|
depends=("${MINGW_PACKAGE_PREFIX}-python")
|
|
makedepends=("${MINGW_PACKAGE_PREFIX}-python-build"
|
|
"${MINGW_PACKAGE_PREFIX}-python-installer"
|
|
"${MINGW_PACKAGE_PREFIX}-python-setuptools")
|
|
checkdepends=("${MINGW_PACKAGE_PREFIX}-python-pytest-asyncio"
|
|
"${MINGW_PACKAGE_PREFIX}-python-pytest")
|
|
source=("https://pypi.org/packages/source/${_realname::1}/${_realname}/${_realname}-${pkgver}.tar.gz")
|
|
sha256sums=('d89f2d8cd8b56dada7d52fa7dc8075baa08fb836560710d38c292a7a3f78c04e')
|
|
|
|
build() {
|
|
cp -r "${_realname}-${pkgver}" "python-build-${MSYSTEM}" && cd "python-build-${MSYSTEM}"
|
|
${MINGW_PREFIX}/bin/python -m build --wheel --skip-dependency-check --no-isolation
|
|
}
|
|
|
|
check() {
|
|
cd "${srcdir}/python-build-${MSYSTEM}"
|
|
PYTHONPATH=. ${MINGW_PREFIX}/bin/pytest .
|
|
}
|
|
|
|
package() {
|
|
cd "${srcdir}/python-build-${MSYSTEM}"
|
|
MSYS2_ARG_CONV_EXCL="--prefix=" \
|
|
${MINGW_PREFIX}/bin/python -m installer --prefix=${MINGW_PREFIX} \
|
|
--destdir="${pkgdir}" dist/*.whl
|
|
|
|
install -Dm644 LICENSE "${pkgdir}${MINGW_PREFIX}/share/licenses/python-${_realname}/LICENSE"
|
|
}
|