68 lines
2.2 KiB
Bash
68 lines
2.2 KiB
Bash
# Contributor: Runar Tenfjord < runar dot tenfjord at gmail dot com >
|
|
|
|
_realname=h5py
|
|
pkgbase=mingw-w64-python-${_realname}
|
|
pkgname=("${MINGW_PACKAGE_PREFIX}-python-${_realname}")
|
|
pkgver=3.15.1
|
|
pkgrel=1
|
|
pkgdesc="General-purpose Python bindings for the HDF5 library (mingw-w64)"
|
|
arch=('any')
|
|
mingw_arch=('mingw64' 'ucrt64' 'clang64' 'clangarm64')
|
|
url="https://www.h5py.org/"
|
|
msys2_repository_url="https://github.com/h5py/h5py/"
|
|
msys2_references=(
|
|
'purl: pkg:pypi/h5py'
|
|
)
|
|
license=('spdx:BSD-3-Clause')
|
|
depends=("${MINGW_PACKAGE_PREFIX}-python"
|
|
"${MINGW_PACKAGE_PREFIX}-python-numpy"
|
|
"${MINGW_PACKAGE_PREFIX}-hdf5")
|
|
makedepends=("${MINGW_PACKAGE_PREFIX}-python-build"
|
|
"${MINGW_PACKAGE_PREFIX}-python-installer"
|
|
"${MINGW_PACKAGE_PREFIX}-python-setuptools"
|
|
"${MINGW_PACKAGE_PREFIX}-cython"
|
|
"${MINGW_PACKAGE_PREFIX}-cc"
|
|
"${MINGW_PACKAGE_PREFIX}-python-pkgconfig"
|
|
"${MINGW_PACKAGE_PREFIX}-pkgconf")
|
|
source=("https://pypi.org/packages/source/${_realname::1}/${_realname}/${_realname}-${pkgver}.tar.gz"
|
|
0001-multi-digit-SOVERSION.patch
|
|
lzf_c.c.patch)
|
|
sha256sums=('c86e3ed45c4473564de55aa83b6fc9e5ead86578773dfbd93047380042e26b69'
|
|
'b393b8cb1efbd4f52d40e14a5c6e736039f3dadc11589b4b9b39edef0eb32a68'
|
|
'6d0126b881b5dcd637146d151341b72aa68eef760092272279072ec0bc4ceca9')
|
|
|
|
apply_patch_with_msg() {
|
|
for _patch in "$@"
|
|
do
|
|
msg2 "Applying $_patch"
|
|
patch -Np1 -i "${srcdir}/$_patch"
|
|
done
|
|
}
|
|
|
|
prepare() {
|
|
cd "${srcdir}/${_realname}-${pkgver}"
|
|
|
|
apply_patch_with_msg \
|
|
0001-multi-digit-SOVERSION.patch \
|
|
lzf_c.c.patch
|
|
}
|
|
|
|
build() {
|
|
cp -r "${_realname}-${pkgver}" "python-build-${MSYSTEM}" && cd "python-build-${MSYSTEM}"
|
|
|
|
H5PY_SETUP_REQUIRES=0 \
|
|
HDF5_DIR=${MINGW_PREFIX} \
|
|
${MINGW_PREFIX}/bin/python -m build --wheel --skip-dependency-check --no-isolation
|
|
}
|
|
|
|
package() {
|
|
cd "${srcdir}/python-build-${MSYSTEM}"
|
|
|
|
MSYS2_ARG_CONV_EXCL="--prefix=" \
|
|
${MINGW_PREFIX}/bin/python -m installer --prefix=${MINGW_PREFIX} \
|
|
--destdir="${pkgdir}" dist/*.whl
|
|
|
|
install -Dm644 licenses/license.txt \
|
|
"${pkgdir}${MINGW_PREFIX}/share/licenses/python-${_realname}/LICENSE.txt"
|
|
}
|