47 lines
1.5 KiB
Bash
47 lines
1.5 KiB
Bash
# Maintainer: @naveen521kk on Github Naveen M K <naveen521kk@gmail.com>
|
|
|
|
_realname=poetry-core
|
|
pkgbase=mingw-w64-python-${_realname}
|
|
pkgname=("${MINGW_PACKAGE_PREFIX}-python-${_realname}")
|
|
pkgver=2.2.1
|
|
pkgrel=1
|
|
pkgdesc="Poetry PEP 517 Build Backend (mingw-w64)"
|
|
arch=('any')
|
|
mingw_arch=('mingw32' 'mingw64' 'ucrt64' 'clang64' 'clangarm64')
|
|
url="https://github.com/python-poetry/poetry-core"
|
|
msys2_repository_url="https://github.com/python-poetry/poetry-core"
|
|
msys2_references=(
|
|
'archlinux: python-poetry-core'
|
|
'purl: pkg:pypi/poetry-core'
|
|
)
|
|
license=('spdx:MIT')
|
|
depends=("${MINGW_PACKAGE_PREFIX}-python")
|
|
makedepends=("${MINGW_PACKAGE_PREFIX}-python-build"
|
|
"${MINGW_PACKAGE_PREFIX}-python-installer")
|
|
checkdepends=("${MINGW_PACKAGE_PREFIX}-python-pytest-mock"
|
|
"${MINGW_PACKAGE_PREFIX}-python-pytest")
|
|
source=("https://pypi.org/packages/source/${_realname::1}/${_realname}/${_realname/-/_}-${pkgver}.tar.gz")
|
|
sha256sums=('97e50d8593c8729d3f49364b428583e044087ee3def1e010c6496db76bd65ac5')
|
|
|
|
build() {
|
|
cp -r "${_realname/-/_}-${pkgver}" "python-build-${MSYSTEM}" && cd "python-build-${MSYSTEM}"
|
|
|
|
python -m build --wheel --skip-dependency-check --no-isolation
|
|
}
|
|
|
|
check() {
|
|
cd "python-build-${MSYSTEM}"
|
|
|
|
python -m pytest || echo "test failed"
|
|
}
|
|
|
|
package() {
|
|
cd "python-build-${MSYSTEM}"
|
|
|
|
MSYS2_ARG_CONV_EXCL="--prefix=" \
|
|
python -m installer --prefix=${MINGW_PREFIX} \
|
|
--destdir="${pkgdir}" dist/*.whl
|
|
|
|
install -D -m644 LICENSE "${pkgdir}${MINGW_PREFIX}"/share/licenses/python-${_realname}/LICENSE
|
|
}
|