45 lines
1.4 KiB
Bash
45 lines
1.4 KiB
Bash
# Contributor: Raed Rizqie <raed.rizqie@gmail.com>
|
|
|
|
_realname=rope
|
|
pkgbase=mingw-w64-python-${_realname}
|
|
pkgname=${MINGW_PACKAGE_PREFIX}-python-${_realname}
|
|
pkgver=1.14.0
|
|
pkgrel=2
|
|
pkgdesc='A python refactoring library (mingw-w64)'
|
|
arch=('any')
|
|
mingw_arch=('mingw64' 'ucrt64' 'clang64' 'clangarm64')
|
|
license=('spdx:LGPL-3.0-only')
|
|
url='https://github.com/python-rope/rope'
|
|
msys2_references=(
|
|
"cpe: cpe:/a:rope_project:rope"
|
|
"purl: pkg:pypi/rope"
|
|
)
|
|
depends=(
|
|
${MINGW_PACKAGE_PREFIX}-python
|
|
${MINGW_PACKAGE_PREFIX}-python-pytoolconfig)
|
|
makedepends=(
|
|
${MINGW_PACKAGE_PREFIX}-python-build
|
|
${MINGW_PACKAGE_PREFIX}-python-installer
|
|
${MINGW_PACKAGE_PREFIX}-python-setuptools)
|
|
source=("https://pypi.org/packages/source/${_realname::1}/${_realname}/${_realname}-${pkgver}.tar.gz")
|
|
sha256sums=('8803e3b667315044f6270b0c69a10c0679f9f322ed8efe6245a93ceb7658da69')
|
|
|
|
build() {
|
|
cp -r "${_realname}-${pkgver}" "python-build-${MSYSTEM}" && cd "python-build-${MSYSTEM}"
|
|
${MINGW_PREFIX}/bin/python -m build --wheel --skip-dependency-check --no-isolation
|
|
}
|
|
|
|
check() {
|
|
cd "${srcdir}/python-build-${MSYSTEM}"
|
|
${MINGW_PREFIX}/bin/python -m unittest
|
|
}
|
|
|
|
package() {
|
|
cd "${srcdir}/python-build-${MSYSTEM}"
|
|
MSYS2_ARG_CONV_EXCL="--prefix=" \
|
|
${MINGW_PREFIX}/bin/python -m installer --prefix=${MINGW_PREFIX} \
|
|
--destdir="${pkgdir}" dist/*.whl
|
|
|
|
install -Dm644 COPYING "${pkgdir}${MINGW_PREFIX}/share/licenses/python-${_realname}/COPYING"
|
|
}
|