49 lines
1.9 KiB
Bash
49 lines
1.9 KiB
Bash
# Maintainer: J. Peter Mugaas <jpmugaas@suddenlink.net>
|
|
|
|
_realname=subunit
|
|
pkgbase=mingw-w64-python-${_realname}
|
|
pkgname=("${MINGW_PACKAGE_PREFIX}-python-${_realname}")
|
|
pkgver=1.4.4
|
|
pkgrel=3
|
|
pkgdesc="Python implementation of subunit test streaming protocol (mingw-w64)"
|
|
arch=('any')
|
|
mingw_arch=('mingw32' 'mingw64' 'ucrt64' 'clang64' 'clangarm64')
|
|
url='https://launchpad.net/subunit'
|
|
msys2_references=(
|
|
'archlinux: python-subunit'
|
|
'purl: pkg:pypi/python-subunit'
|
|
)
|
|
license=('spdx:Apache-2.0 OR BSD-3-Clause')
|
|
depends=("${MINGW_PACKAGE_PREFIX}-python"
|
|
"${MINGW_PACKAGE_PREFIX}-python-iso8601"
|
|
"${MINGW_PACKAGE_PREFIX}-python-testtools")
|
|
makedepends=("${MINGW_PACKAGE_PREFIX}-python-build"
|
|
"${MINGW_PACKAGE_PREFIX}-python-installer"
|
|
"${MINGW_PACKAGE_PREFIX}-python-setuptools")
|
|
checkdepends=("${MINGW_PACKAGE_PREFIX}-python-fixtures"
|
|
"${MINGW_PACKAGE_PREFIX}-python-hypothesis"
|
|
"${MINGW_PACKAGE_PREFIX}-python-testscenarios")
|
|
options=('!strip')
|
|
source=("https://pypi.io/packages/source/p/python-subunit/python-subunit-${pkgver}.tar.gz")
|
|
sha512sums=('67f8dd012d33ae719a4b4ff45981fcc98ce268f2aa3f1c6db80af271439cfd9811bb0d27b08b20a7317d24decb416b3ac34ea8bc8baf7bd82fea7d6a64ff6979')
|
|
|
|
build() {
|
|
cp -r "python-${_realname}-${pkgver}" "python-build-${MSYSTEM}" && cd "python-build-${MSYSTEM}"
|
|
${MINGW_PREFIX}/bin/python -m build --wheel --skip-dependency-check --no-isolation
|
|
}
|
|
|
|
check() {
|
|
cd "${srcdir}/python-build-${MSYSTEM}"
|
|
PYTHONPATH="$PWD/build/lib" python -m testtools.run subunit.test_suite || warning "Tests failed"
|
|
}
|
|
|
|
package() {
|
|
cd "${srcdir}/python-build-${MSYSTEM}"
|
|
|
|
MSYS2_ARG_CONV_EXCL="--prefix=" \
|
|
${MINGW_PREFIX}/bin/python -m installer --prefix=${MINGW_PREFIX} \
|
|
--destdir="${pkgdir}" dist/*.whl
|
|
|
|
install -Dm644 COPYING "${pkgdir}${MINGW_PREFIX}/share/licenses/python-${_realname}/COPYING"
|
|
}
|