62308009e7
Except the provides in libc++ for backwards compat. No rebuilds now, as that's not worth the resources.
73 lines
2.3 KiB
Bash
73 lines
2.3 KiB
Bash
# Maintainer: umarcor <unai.martinezcorral@ehu.eus>
|
|
|
|
_realname=serial-studio
|
|
pkgbase=mingw-w64-${_realname}
|
|
pkgname="${MINGW_PACKAGE_PREFIX}-${_realname}"
|
|
pkgver=3.0.6
|
|
pkgrel=1
|
|
pkgdesc="Multi-purpose serial data visualization & processing program (mingw-w64)"
|
|
arch=('any')
|
|
mingw_arch=('ucrt64' 'clang64' 'clangarm64')
|
|
url="https://serial-studio.github.io/"
|
|
msys2_repository_url="https://github.com/Serial-Studio/Serial-Studio"
|
|
license=('spdx:MIT')
|
|
groups=("${MINGW_PACKAGE_PREFIX}-eda")
|
|
depends=("${MINGW_PACKAGE_PREFIX}-cc-libs"
|
|
"${MINGW_PACKAGE_PREFIX}-qt6-base"
|
|
"${MINGW_PACKAGE_PREFIX}-qt6-connectivity"
|
|
"${MINGW_PACKAGE_PREFIX}-qt6-declarative"
|
|
"${MINGW_PACKAGE_PREFIX}-qt6-graphs"
|
|
"${MINGW_PACKAGE_PREFIX}-qt6-serialport")
|
|
makedepends=(
|
|
"${MINGW_PACKAGE_PREFIX}-cc"
|
|
"${MINGW_PACKAGE_PREFIX}-cmake"
|
|
"${MINGW_PACKAGE_PREFIX}-qt6-location"
|
|
"${MINGW_PACKAGE_PREFIX}-qt6-positioning"
|
|
"${MINGW_PACKAGE_PREFIX}-qt6-svg"
|
|
"${MINGW_PACKAGE_PREFIX}-qt6-tools"
|
|
)
|
|
source=("https://github.com/${_realname}/${_realname}/archive/v${pkgver}/${_realname}-${pkgver}.tar.gz"
|
|
001-fix-build-and-package.patch)
|
|
sha256sums=('3141605fae37869f4375349bbfa0242ae66b3914ead31ea11866ab3fac2f20e4'
|
|
'c5dc4ca6f5539aea8a88a1788b36743f4a477479996028b342477f6eb4b57874')
|
|
|
|
prepare() {
|
|
cd "${srcdir}/${_realname}-${pkgver}"
|
|
|
|
patch -p1 -i "${srcdir}"/001-fix-build-and-package.patch
|
|
}
|
|
|
|
build() {
|
|
mkdir -p "${srcdir}/build-${MSYSTEM}" && cd "${srcdir}/build-${MSYSTEM}"
|
|
|
|
declare -a _extra_config
|
|
if check_option "debug" "n"; then
|
|
_extra_config+=("-DCMAKE_BUILD_TYPE=Release")
|
|
else
|
|
_extra_config+=("-DCMAKE_BUILD_TYPE=Debug")
|
|
fi
|
|
|
|
MSYS2_ARG_CONV_EXCL="-DCMAKE_INSTALL_PREFIX=" \
|
|
${MINGW_PREFIX}/bin/cmake -Wno-dev \
|
|
-G"Ninja" \
|
|
-DCMAKE_INSTALL_PREFIX=${MINGW_PREFIX} \
|
|
-DPRODUCTION_OPTIMIZATION=ON \
|
|
${_extra_config[@]} \
|
|
../${_realname}-${pkgver}
|
|
|
|
${MINGW_PREFIX}/bin/cmake --build .
|
|
}
|
|
|
|
check() {
|
|
"${srcdir}"/build-${MSYSTEM}/release/Serial-Studio.exe --help
|
|
}
|
|
|
|
package() {
|
|
cd "${srcdir}/build-${MSYSTEM}"
|
|
|
|
DESTDIR="${pkgdir}" ${MINGW_PREFIX}/bin/cmake --install .
|
|
|
|
install -Dm644 "${srcdir}"/${_realname}-${pkgver}/LICENSE.md \
|
|
"${pkgdir}"${MINGW_PREFIX}/share/licenses/${_realname}/LICENSE.md
|
|
}
|