54 lines
1.7 KiB
Bash
54 lines
1.7 KiB
Bash
# Maintainer: Konstantin Podsvirov <konstantin@podsvirov.su>
|
|
|
|
_realname=sqlite-orm
|
|
pkgbase=mingw-w64-${_realname}
|
|
pkgname=("${MINGW_PACKAGE_PREFIX}-${_realname}")
|
|
pkgver=1.9.1
|
|
pkgrel=1
|
|
pkgdesc="SQLite ORM light header only library for modern C++ (mingw-w64)"
|
|
arch=('any')
|
|
mingw_arch=('mingw64' 'ucrt64' 'clang64' 'clangarm64')
|
|
url="https://github.com/fnc12/sqlite_orm"
|
|
license=('spdx:AGPL-3.0-or-later')
|
|
makedepends=("${MINGW_PACKAGE_PREFIX}-cc"
|
|
"${MINGW_PACKAGE_PREFIX}-cmake"
|
|
"${MINGW_PACKAGE_PREFIX}-ninja")
|
|
depends=("${MINGW_PACKAGE_PREFIX}-sqlite3")
|
|
source=("${url}/archive/v${pkgver}/${_realname/-/_}-${pkgver}.tar.gz")
|
|
sha256sums=('de2db80e4f716a27c4e1f4cb8a356394e428676c98c90b0577b0431107d3cccf')
|
|
|
|
build() {
|
|
mkdir -p "${srcdir}/build-${MSYSTEM}" && cd "${srcdir}/build-${MSYSTEM}"
|
|
|
|
declare -a _extra_config
|
|
if check_option "debug" "n"; then
|
|
_extra_config+=("-DCMAKE_BUILD_TYPE=Release")
|
|
else
|
|
_extra_config+=("-DCMAKE_BUILD_TYPE=Debug")
|
|
fi
|
|
|
|
MSYS2_ARG_CONV_EXCL="-DCMAKE_INSTALL_PREFIX=" \
|
|
${MINGW_PREFIX}/bin/cmake.exe \
|
|
-GNinja \
|
|
-DCMAKE_INSTALL_PREFIX=${MINGW_PREFIX} \
|
|
-DBUILD_TESTING=OFF \
|
|
-DBUILD_EXAMPLES=OFF \
|
|
"${_extra_config[@]}" \
|
|
../${_realname/-/_}-${pkgver}
|
|
|
|
${MINGW_PREFIX}/bin/cmake.exe --build .
|
|
}
|
|
|
|
package() {
|
|
cd "${srcdir}/build-${MSYSTEM}"
|
|
|
|
DESTDIR="${pkgdir}" ${MINGW_PREFIX}/bin/cmake.exe --install .
|
|
|
|
install -Dm644 "${srcdir}/${_realname/-/_}-${pkgver}/README.md" \
|
|
"${pkgdir}${MINGW_PREFIX}/share/doc/${_realname}/README.md"
|
|
install -Dm644 "${srcdir}/${_realname/-/_}-${pkgver}/LICENSE" \
|
|
"${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/LICENSE"
|
|
}
|
|
|
|
# vim:set ts=2 sw=2 et:
|