54 lines
1.9 KiB
Bash
54 lines
1.9 KiB
Bash
# Maintainer: Taozuhong <taozuhong@gmail.com>
|
|
|
|
_realname=vala-language-server
|
|
pkgbase=mingw-w64-${_realname}
|
|
pkgname="${MINGW_PACKAGE_PREFIX}-${_realname}"
|
|
pkgver=0.48.7
|
|
pkgrel=2
|
|
pkgdesc="Vala Language Server for the Vala programming language (mingw-w64)"
|
|
arch=('any')
|
|
mingw_arch=('mingw64' 'ucrt64' 'clang64' 'clangarm64')
|
|
url="https://github.com/vala-lang/vala-language-server"
|
|
license=('spdx:LGPL-2.1-or-later')
|
|
makedepends=("${MINGW_PACKAGE_PREFIX}-cc"
|
|
"${MINGW_PACKAGE_PREFIX}-meson"
|
|
"${MINGW_PACKAGE_PREFIX}-pkgconf"
|
|
"${MINGW_PACKAGE_PREFIX}-scdoc")
|
|
depends=("${MINGW_PACKAGE_PREFIX}-jsonrpc-glib"
|
|
"${MINGW_PACKAGE_PREFIX}-glib2"
|
|
"${MINGW_PACKAGE_PREFIX}-json-glib"
|
|
"${MINGW_PACKAGE_PREFIX}-libgee"
|
|
"${MINGW_PACKAGE_PREFIX}-vala")
|
|
optdepends=("${MINGW_PACKAGE_PREFIX}-meson: to support meson projects")
|
|
source=("https://github.com/vala-lang/vala-language-server/archive/${pkgver}/${_realname}-${pkgver}.tar.gz")
|
|
sha256sums=('6e848334accd27566843d56db15bedcf7529dc68e416d23d3b4e9fc522019c68')
|
|
|
|
build() {
|
|
mkdir -p "${srcdir}/build-${MSYSTEM}" && cd "${srcdir}/build-${MSYSTEM}"
|
|
|
|
declare -a _extra_config
|
|
if check_option "debug" "n"; then
|
|
_extra_config+=("--buildtype=release")
|
|
else
|
|
_extra_config+=("--buildtype=debug")
|
|
fi
|
|
|
|
CFLAGS+=" -Wno-int-conversion -Wno-incompatible-function-pointer-types" \
|
|
MSYS2_ARG_CONV_EXCL="--prefix=" \
|
|
${MINGW_PREFIX}/bin/meson.exe setup \
|
|
--prefix="${MINGW_PREFIX}" \
|
|
"${_extra_config[@]}" \
|
|
--wrap-mode=nodownload \
|
|
--default-library=both \
|
|
-Dman_pages=enabled \
|
|
../${_realname}-${pkgver}
|
|
|
|
${MINGW_PREFIX}/bin/meson.exe compile
|
|
}
|
|
|
|
package() {
|
|
cd "${srcdir}/build-${MSYSTEM}"
|
|
DESTDIR="${pkgdir}" ${MINGW_PREFIX}/bin/meson.exe install
|
|
install -Dm644 "${srcdir}/${_realname}-${pkgver}/COPYING" "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/COPYING"
|
|
}
|