75 lines
2.2 KiB
Bash
75 lines
2.2 KiB
Bash
# Maintainer: J. Peter Mugaas <jpmugaas@suddenlink.net>
|
|
|
|
_realname=directxtex
|
|
pkgbase=mingw-w64-${_realname}
|
|
pkgname=("${MINGW_PACKAGE_PREFIX}-${_realname}")
|
|
# Version from CMakeLists.txt
|
|
pkgver=2.0.6
|
|
_tag=oct2024
|
|
pkgrel=2
|
|
pkgdesc="DirectXTex texture processing library (mingw-w64)"
|
|
arch=('any')
|
|
mingw_arch=('mingw64' 'ucrt64' 'clang64' 'clangarm64')
|
|
url='http://go.microsoft.com/fwlink/?LinkId=248926'
|
|
msys2_repository_url="https://github.com/microsoft/DirectXTex"
|
|
msys2_references=(
|
|
'aur: mingw-w64-directxtex'
|
|
)
|
|
license=('spdx:MIT')
|
|
depends=("${MINGW_PACKAGE_PREFIX}-directx-headers"
|
|
"${MINGW_PACKAGE_PREFIX}-directxmath"
|
|
"${MINGW_PACKAGE_PREFIX}-openexr")
|
|
makedepends=("${MINGW_PACKAGE_PREFIX}-cc"
|
|
"${MINGW_PACKAGE_PREFIX}-cmake"
|
|
"${MINGW_PACKAGE_PREFIX}-ninja"
|
|
"${MINGW_PACKAGE_PREFIX}-efxc2")
|
|
source=("https://github.com/microsoft/DirectXTex/archive/$_tag/${_realname}-${_tag}.tar.gz")
|
|
sha256sums=('0caea49c52bba24eb6025ad1f46c9aa00224e91c075b55a21b738a23ed5fedfe')
|
|
|
|
build() {
|
|
mkdir -p "${srcdir}/build-${MSYSTEM}" && cd "${srcdir}/build-${MSYSTEM}"
|
|
|
|
declare -a extra_config
|
|
if check_option "debug" "n"; then
|
|
extra_config+=("-DCMAKE_BUILD_TYPE=Release")
|
|
else
|
|
extra_config+=("-DCMAKE_BUILD_TYPE=Debug")
|
|
fi
|
|
|
|
if [ "${CARCH}" == "x86_64" ]; then
|
|
extra_config+=("-DDIRECTX_ARCH=x64")
|
|
fi
|
|
if [ "${CARCH}" == "aarch64" ]; then
|
|
extra_config+=("-DDIRECTX_ARCH=arm64")
|
|
fi
|
|
|
|
#DBUILD_DX11 requires fxc.exe but that's not available.
|
|
MSYS2_ARG_CONV_EXCL="-DCMAKE_INSTALL_PREFIX=" \
|
|
"${MINGW_PREFIX}"/bin/cmake.exe \
|
|
-GNinja \
|
|
-DCMAKE_INSTALL_PREFIX="${MINGW_PREFIX}" \
|
|
-DBUILD_DX11=ON \
|
|
-DBUILD_DX12=ON \
|
|
-DBUILD_TOOLS=ON \
|
|
-DENABLE_OPENEXR_SUPPORT=ON \
|
|
"${extra_config[@]}" \
|
|
../${_realname}-${_tag}
|
|
|
|
"${MINGW_PREFIX}"/bin/cmake.exe --build .
|
|
}
|
|
|
|
check() {
|
|
cd "${srcdir}/build-${MSYSTEM}"
|
|
|
|
"${MINGW_PREFIX}"/bin/cmake.exe --build . --target test
|
|
}
|
|
|
|
package() {
|
|
cd "${srcdir}/build-${MSYSTEM}"
|
|
|
|
DESTDIR="${pkgdir}" "${MINGW_PREFIX}"/bin/cmake.exe --install .
|
|
|
|
install -Dm644 "${srcdir}"/${_realname}-${_tag}/LICENSE \
|
|
"${pkgdir}"${MINGW_PREFIX}/share/licenses/${_realname}/LICENSE
|
|
}
|