42 lines
1.6 KiB
Bash
42 lines
1.6 KiB
Bash
# Contributor: Christoph Reiter <reiter.christoph@gmail.com>
|
|
|
|
_realname=attrs
|
|
pkgbase=mingw-w64-python-${_realname}
|
|
pkgname=("${MINGW_PACKAGE_PREFIX}-python-${_realname}")
|
|
pkgver=25.4.0
|
|
pkgrel=1
|
|
pkgdesc='Attributes without boilerplate (mingw-w64)'
|
|
arch=('any')
|
|
mingw_arch=('mingw64' 'ucrt64' 'clang64' 'clangarm64')
|
|
url='https://www.attrs.org/'
|
|
msys2_repository_url='https://github.com/python-attrs/attrs'
|
|
msys2_changelog_url='https://www.attrs.org/en/stable/changelog.html'
|
|
msys2_references=(
|
|
'archlinux: python-attrs'
|
|
'gentoo: dev-python/attrs'
|
|
'purl: pkg:pypi/attrs'
|
|
)
|
|
license=('spdx:MIT')
|
|
depends=("${MINGW_PACKAGE_PREFIX}-python")
|
|
makedepends=("${MINGW_PACKAGE_PREFIX}-python-build"
|
|
"${MINGW_PACKAGE_PREFIX}-python-installer"
|
|
"${MINGW_PACKAGE_PREFIX}-python-hatchling"
|
|
"${MINGW_PACKAGE_PREFIX}-python-hatch-vcs"
|
|
"${MINGW_PACKAGE_PREFIX}-python-hatch-fancy-pypi-readme")
|
|
source=("https://pypi.org/packages/source/${_realname::1}/${_realname}/${_realname}-${pkgver}.tar.gz")
|
|
sha256sums=('16d5969b87f0859ef33a48b35d55ac1be6e42ae49d5e853b597db70c35c57e11')
|
|
|
|
build() {
|
|
cp -r "${_realname}-${pkgver}" "python-build-${MSYSTEM}" && cd "python-build-${MSYSTEM}"
|
|
${MINGW_PREFIX}/bin/python -m build --wheel --skip-dependency-check --no-isolation
|
|
}
|
|
|
|
package() {
|
|
cd "${srcdir}/python-build-${MSYSTEM}"
|
|
MSYS2_ARG_CONV_EXCL="--prefix=" \
|
|
${MINGW_PREFIX}/bin/python -m installer --prefix=${MINGW_PREFIX} \
|
|
--destdir="${pkgdir}" dist/*.whl
|
|
|
|
install -Dm644 "${srcdir}/${_realname}-${pkgver}/LICENSE" "${pkgdir}${MINGW_PREFIX}/share/licenses/python-${_realname}/LICENSE"
|
|
}
|